C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MGETMAPC    GET MAP CHAR DATA FOR ONE VARIABLE
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 02-05-01
C
C ABSTRACT: READ MAP CHARACTER DATA FOR ALL STATIONS FOR
C   ONE VARIABLE AND TIME.
C
C PROGRAM HISTORY LOG:
C   02-05-01  M. BARTH    ORIGINAL VERSION
C   03-07-02  M. BARTH    FIXED A COMMENT THAT WENT PAST COLUMN 72.
C                         THIS COULD HAVE CAUSED TROUBLE ON SOME
C                         COMPILERS.
C   06-09-20  L. BENJAMIN ADDED TIME STRING TO MAP DATASET.
C
C USAGE:    CALL MGETMAPC (ATIME,VCODE,NSTA,CDATA,STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C     VCODE    - C       VARIABLE CODE NAME
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     CDATA    - CA      ARRAY OF RETURNED CHARACTER DATA
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS MAP NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, MGETVCN, MMAPBEAMC
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT AND MMAPSTA BEFORE CALLING THIS
C     ROUTINE.  MMAPSTA SHOULD BE CALLED FIRST WHENEVER ACCESS TO
C     A NEW TIME IS DESIRED.  IT STORES INFO IN THE STRCCOM COMMON
C     THAT IS USED BY THIS ROUTINE TO FIGURE OUT WHICH RECORDS ARE
C     NEEDED ON NETCDF FILES OPENED BY MMAPSTA.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH THE MAXIMUM
C     NUMBER OF STATIONS POSSIBLE FOR THIS DATATYPE (madiscon.f),
C     AND TO MATCH THE DIMENSIONS OF THE DESIRED CHARACTER
C     VARIABLE.  SEE THE MADIS USER'S GUIDE TO SEE WHAT DIMENSIONS
C     SHOULD BE USED FOR THE CHARACTER VARIABLES.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MGETMAPC(ATIME,VCODE,NSTA,CDATA,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME
      CHARACTER*(*) VCODE
      INTEGER NSTA,STATUS
      CHARACTER*1 CDATA(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,FNUM,DSN,LEN1REC,CD,VCN
      LOGICAL HAVE_ANY
      CHARACTER*1 CTMP(MAX_CHAR_VLEN_P*MXUAPT_P),VCT

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(CTMP,TMP_L1_C1)

C     ------------------------------------------------------------------
C     SET THE CURRENT DATASET TYPE AND DATABASE TYPE TO MAP.
C     ------------------------------------------------------------------
      CDTYPE = MAP_DS_P
      CD = MAP_DS_P
      CDBTYPE = UAPT_DBTYPE(CD)
      DSN = MAX_SFCDSET_P + CD

C     ------------------------------------------------------------------
C     IF THE MAP SUBSYSTEM HASN'T BEEN INITIALIZED, OR IF THE
C     REQUESTED TIME DOESN'T MATCH THE TIME LAST PROCESSED BY MMAPSTA,
C     OR IF THE VCODE IS ILLEGAL, OR IF THE VARIABLE'S NOT CHARACTER 
C     DATA TYPE, RETURN WITH ERROR.
C     ------------------------------------------------------------------
      IF(UAPT_INIT(CD).NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MGETMAPC: SELECTED SUBSYSTEM NOT INITIALIZED'//
     1               ' - '//UAPTDSET_NAME(CD))
         GO TO 900
      ELSE IF(ATIME.NE.LAST_UAPT_ATIME(CD).OR.ATIME.EQ.'         ')THEN
         STATUS = TIME_NOTINIT_P
         CALL MERROR('MGETMAPC: TIME NOT INITIALIZED BY MMAPSTA'//
     1               ' - '//UAPTDSET_NAME(CD))
         GO TO 900
      ENDIF

      CALL MGETVCN(VCODE,VCN,VCT,STATUS)
      IF(STATUS.NE.SUCCESS_P)GO TO 900
      
      IF(VCN.EQ.MAPCST_1_VN_P.OR.VCN.EQ.MAPCST_2_VN_P.OR.
     1     VCN.EQ.MAPCST_3_VN_P.OR.VCN.EQ.MAPCST_R_VN_P)THEN
         CALL  MMAPTIME(VCN,ATIME,NSTA,CDATA,STATUS)
         RETURN
      ENDIF

      IF(VDTYPE(VCN,DSN).NE.'c')THEN
         STATUS = INV_DTYPE_P
         CALL MERROR('MGETMAPC: INVALID VARIABLE DATA TYPE')
         GO TO 900
      ENDIF

      NSTA = UAPT_LNUM(CD)
      IF(NSTA.EQ.0)THEN
         STATUS = NO_DATA_P
         GO TO 900
      ENDIF

      FNUM = 0

C     ------------------------------------------------------------------
C     NOTE THAT WE LOOP THROUGH UAPT_FNUM TO SEE WHICH FILES ARE NEEDED
C     AND NOT THROUGH UAPT_NFILES.  THIS IS DONE AS JUST BECAUSE A FILE
C     GOT READ DOESN'T MEAN ANY OF ITS RECORDS ACTUALLY WERE EXTRACTED
C     WHEN ALL THE FILTERING WAS DONE IN MMAPSTA.  THEREFORE, WE'LL
C     ONLY PROCESS EACH FILE WITH RECORDS IN USE.
C     ------------------------------------------------------------------
      DO 100 I = 1, NSTA

C     ------------------------------------------------------------------
C     ALREADY HANDLED THIS FILE.
C     ------------------------------------------------------------------
         IF(FNUM.EQ.UAPT_FNUM(I,CD))GO TO 100

C     ------------------------------------------------------------------
C     IF THIS IS THE FIRST TIME WE'VE BEEN HERE, FILL IN BLANKS IN THE
C     CALLER'S ARRAY.
C     ------------------------------------------------------------------

         IF(FNUM.EQ.0)THEN

            FNUM = UAPT_FNUM(I,CD)

            DO 118 J = 1, NSTA

               DO 119 K = 1, VCLEN(VCN,DSN)

                  CDATA((J-1)*VCLEN(VCN,DSN)+K) = ' '

 119           CONTINUE

 118        CONTINUE

         ELSE

            FNUM = UAPT_FNUM(I,CD)

         ENDIF

C     ------------------------------------------------------------------
C     THE ONLY MAP CHARACTER VARIABLES ARE THE BEAM NAMES.  CALL A 
C     SUBROUTINE TO READ THE VARIABLE AND EXTRACT ONLY THE BEAM OF 
C     INTEREST.  IF THERE'S AN ERROR, THE SUBROUTINE WILL HAVE SET 
C     STATUS & CALLED MERROR.  IF THERE ISN'T AN ERROR, INDICATE THAT WE
C     ACTUALLY READ SOMETHING.
C     ------------------------------------------------------------------
         CALL MMAPBEAMC(VCN,DSN,FNUM,CTMP,LEN1REC,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900

         HAVE_ANY = .TRUE.

C     ------------------------------------------------------------------
C     EXTRACT DESIRED RECORDS INTO CALLER'S ARRAY.  REPLACE NULLS WITH
C     BLANKS (FOR FORTRAN USERS).
C     ------------------------------------------------------------------
         DO 120 J = I, NSTA

            IF(UAPT_FNUM(J,CD).NE.FNUM)GO TO 100

            DO 121 K = 1, LEN1REC

               IF(ICHAR(CTMP((UAPT_RNUM(J,CD)-1)*LEN1REC+K)).NE.0)THEN
                  CDATA((J-1)*VCLEN(VCN,DSN)+K) =
     1                 CTMP((UAPT_RNUM(J,CD)-1)*LEN1REC+K)
               ELSE
                  CDATA((J-1)*VCLEN(VCN,DSN)+K) = ' '
               ENDIF

 121        CONTINUE

            IF(J.EQ.NSTA)GO TO 900

 120     CONTINUE

 100  CONTINUE

 900  IF(STATUS.NE.SUCCESS_P)THEN

         NSTA = 0

      ELSE IF(.NOT.HAVE_ANY)THEN

         STATUS = NO_DATA_P
         NSTA = 0

      ENDIF

      RETURN
      END

C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
