C$$$  MAIN PROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C MAIN PROGRAM:  ACARSPDUMP  Dump & tutorial program for MADIS ACARSP
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 04-06-17
C
C ABSTRACT: Dump MADIS ACARS profiles station info, observations, and 
C   quality control (QC) information for a single time, based on the 
C   user's selections specified in a text parameter file.  The program 
C   is also meant as a tutorial to demonstrate how a user can use the 
C   MADIS library calls to write his or her own programs.
C
C PROGRAM HISTORY LOG:
C   04-06-17  M. BARTH  Original version -- MADIS Version 2.5
C   04-10-15  L. BENJAM V2.7 - Changed comment re available datasets 
C                              and removed ipvd.
C   05-10-26  L. BENJAM V2.7 - Changed comment re available datasets 
C   05-11-18  L. BENJAM V3.0 - Changed comment re available datasets 
C   08-07-25  L. BENJAM V3.7 - Changed comment re available datasets 
C   09-09-29  L. BENJAM V3.9 - Fixed tamdar RH variable.
C USAGE:
C   INPUT FILES: (for the entire program)
C
C     acarspdump.par   Parameter file (in current directory) with
C                      user's selections.
C
C     MADIS initialization files in MADIS_STATIC directory   
C
C     MADIS observation files under MADIS_DATA directories
C
C   OUTPUT FILES:
C
C     acarspdump.txt   Text output of station info, obs & QC
C
C     standard output  Log of what was done, errors
C
C SUBPROGRAMS CALLED:
C     LIBRARY: - MADISLIB:  MINIT, MSETWIN, MSETDOM, MSETQC, MTRNTIM, 
C                           MACARSPSTA, MGETIJ, MGENVCN, MGETVCN, 
C                           MGETACARSP, MGETACARSPC, M_MKFNAM
C
C REMARKS:
C
C   1) This program can be used to exercise all options included in the
C      MADIS library for ACARS profile data.  It is also meant to be 
C      used as a tutorial to demonstrate how a user can write his or her
C      own programs.  
C
C   2) See the INSTALL.* files in the MADIS doc directory for 
C      instructions on how to install and build the MADIS library and 
C      programs (INSTALL.unix for Unix/Linux, INSTALL.windows for
C      Windows).
C
C   3) See the acarspdump_usage.txt file in the MADIS doc directory for
C      instructions on how to set up a parameter file and run the
C      program.
C    
C   4) The ACARS profiles are data taken during aircraft taking off
C      and landing at airports.  These data are organized into
C      profiles associated with the location of the airports.  Note
C      that all of the data are also available in the MADIS ACARS
C      files, which also contains flight-level data.  Therefore users
C      whose applications do not need the data organized into profiles
C      should use the ACARS files instead of the profiles.
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN 77 + EXTENSIONS
C   MACHINE: UNIX
C
C$$$
C-----------------------------------------------------------------------
C
C     Declarations notes:
C
C     1) Key constants:
C
C       - 0              successful status return
C       - 6              internal MADIS ACARS profiles dataset code num
C       - 999999.0       missing data flag
C       - 1000           maximum number of ACARS profiles station-time
C                        records possible that can be returned in a 
C                        single time-windowed retrieval
C       - 200            maximum number of levels in a profile
C
      implicit none

      integer success_p,acarsp_ds_p
      real miss_p
      parameter (success_p = 0)
      parameter (acarsp_ds_p = 6)
      parameter (miss_p = 999999.0)
      
      integer istatus,i,j,k,l,line
      integer nsta,nvar,nobs,idb,tform,ctime
      character*10 stanam(1000)
      character*9 atime
      character*6 db
      character*9 timeob(1000)
      integer wmoid(1000)
      real lat(1000),lon(1000),elev(1000)
      integer nlevels(1000)

      real rdata200(200,1000,4)
      integer qca200(200,1000,4),qcr200(200,1000,4)
      character*1 qcd200(200,1000,4)

      real rdata1(1000,4)
      integer qca1(1000,4),qcr1(1000,4)
      character*1 qcd1(1000,4)

      equivalence (rdata200,rdata1)
      equivalence (qca200,qca1)
      equivalence (qcr200,qcr1)
      equivalence (qcd200,qcd1)

      character*51 staloc(1000)
      character*12 tailnum(1000)
      character*9  atailnum(1000)
      equivalence (tailnum,atailnum)
      character*13 flnum(1000)
      character*217 oline
      integer vcn,profile_type(4)
      character*7 vcode(4)
      character*21 vcstr(4)
      character*1 vtype(4),c
      character*13 tstr
      character*70 vline
      integer minbck,minfwd,recwin,qctyp,idmtyp
      real dummy,ri(1000),rj(1000)
      integer idummy,time,ising
      real rpar(7)
      integer ipar(2)
      character*10 singsta
      character*63 twstr(0:4)
      integer twstrlen(0:4)
      character*16 qcstr(0:2)

      data twstr/
     1 'Return all records within the file containing nominal time',  
     2 'Return one record per fixed station, closest to nominal time',
     3'Return one record per fixed station, closest to start of window',
     4 'Return one record per fixed station, closest to end of window',
     5 'Return all records in window'/
      data twstrlen/58,60,63,61,28/
      data qcstr/'No Filter','Coarse','Screened'/

C-----------------------------------------------------------------------
C PROGRAM SETUP
C -------------
C
C     Open an output file for this program.

      open(unit=1,file='acarspdump.txt',status='UNKNOWN')

C     Open the parameter file that will specify the user's selections.

      open(unit=2,file='acarspdump.par',status='OLD')

C-----------------------------------------------------------------------
C MANDATORY MADIS INITIALIZATION
C -----------------------------
C
C     Mandatory initialization which must be done before
C     any other MADIS library calls.
C
C     Initialize the MADIS ACARS profiles subsystem
C     ---------------------------------------------
C
C     The user selects the "subsystem" to be initialized by
C     specifying the following arguments to the MINIT call:
C
C     1) Name of the subsystem:
C
C        'SFC'        Surface
C        'RAOB'       Radiosonde
C        'NPN'        NOAA Profiler Network   
C        'ACARS'      Aircraft data (ACARS, AMDARS, etc.)
C        'ACARSP'     Aircraft data profiles at airports  (used here)
C        'MAP'        Multi-Agency Profilers
C        'HYDRO'      Hydro
C        'RDMTR'      Radiometer              
C        'SATWND'     Satellite wind
C        'SATSND'     Satellite soundings
C        'SATRAD'     Satellite radiance
C        'SNOW'       Snow
C        'WISDOM'     Wisdom balloon wind
C
C     2) Name of the database:
C
C        'FSL'        Data obtained from FSL
C        'AWIPS'      Data obtained from AWIPS
C
C        Note that the list of variables with QC found in the MADIS
C        documentation applies to the FSL database.  For the AWIPS
C        database, the only QC is on sfc mesonet data.  Otherwise, the
C        QC information returned by API calls will indicate that no
C        QC has been applied.
C
C     3) Error handling (.true./.false.):
C
C        If ".true.", then error messages will be written to standard
C        output.  If ".false.", no error messages will be output (but
C        ISTATUS will still contain an error code).  The error codes
C        can be found in errors.txt in the doc directory.

C     PAR FILE INPUT:  Database ('FSL' or 'AWIPS')

C     The necessary inputs are found in the parameter file, along with
C     a number of lines of explanation, section delimiters, etc. meant
C     to aid readability.  Throughout this program, we'll be skipping
C     non-input lines, reading necessary inputs, and checking for I/O
C     errors.  Otherwise, the validity of most of user's choices will
C     be tested by the affected MADIS library routines.  Invalid choices
C     will be reported to standard output, and in most cases, the
C     program will then stop.

      line = 0
      do i = 1, 3
         line = line + 1
         read(2,*,err=825,end=850)
      enddo
      line = line + 1
      read(2,145,err=825,end=850)db
 145  format(a)

      write(*,500)'MADIS ACARSPDUMP Activity Log'
 500  format(1x,a)
      write(*,500)'-----------------------------'

      write(*,501)'Database'
 501  format(/,1x,a)
      write(*,401)db
 401  format(3x,a)

      CALL MINIT('ACARSP',db,.true.,istatus)
      if(istatus.ne.success_p)stop

      if(db(1:3).eq.'FSL')then
         idb = 0
      else if(db(1:5).eq.'AWIPS')then
         idb = 1
      endif

C-----------------------------------------------------------------------
C OPTIONAL MADIS SETUP CALLS
C -------------------------
C
C     Optional calls to limit which obs MADIS will return.
C     These can be selected at any time in the code,
C     and will then take effect upon the next call to
C     MACARSPSTA (see below).  The default behavior (what
C     happens if you don't call the routine) is described
C     below.
C
C     Select time window
C     ------------------
C
C     The user selects the nominal time of the data to be returned
C     when using MADIS routines to read obs and station information.
C     (In the ACARS profiles context, a "station" is an airport.)
C     Time "windowing" is used so that the MADIS routines will
C     know how close in time each station's observation time needs
C     to be to the nominal time in order to be included, and whether
C     or not duplicate records from the same station that are within
C     the time window should be included.  The time window is
C     specified with the MSETWIN subroutine, which allows the user
C     to select the number of minutes before and after the nominal
C     time to be used for the window, and how duplicates should
C     be handled.  For more details, see msetwin.txt in the doc
C     directory.
C
C     If MSETWIN is not called, the default will be to return all
C     records where the observation time is during the hour specified
C     in the file's time.  This will return all records in a standard
C     FSL hourly ACARS profiles file, e.g., with a nominal time of 
C     1200 UTC data time-stamped 1200 through 1259 will be returned.
C
C     Profiles from planes arriving or departing from the same
C     airport can produce observation times around the hour, and 
C     many airports report multiple times per hour, so different time 
C     window specifications can produce very different sets of data.
C
C     The following sample MSETWIN call will return only one record 
C     per station within the specified time window (-30 minutes -->
C     nominal time --> +30 minutes).  If a station has multiple reports
C     within the time window, only the latest one within the window
C     will be returned (RECWIN = 3).
C
C     Sample MSETWIN call:
C
C     minbck = -30
C     minfwd = 30
C     recwin = 3
C     CALL MSETWIN(minbck,minfwd,recwin,istatus)

C     PAR FILE INPUT:  Time window parameters (minbck, minfwd, recwin)
C                      [set all to 0 for default]

      do i = 1, 3
         line = line + 1
         read(2,*,err=825,end=850)
      enddo

      line = line + 1
      read(2,*,err=825,end=850)minbck
      line = line + 1
      read(2,*,err=825,end=850)minfwd
      line = line + 1
      read(2,*,err=825,end=850)recwin

      write(*,501)'Time Window'

      if(recwin.ge.0.and.recwin.le.4)then

         write(*,401)twstr(recwin)(1:twstrlen(recwin))

         if(minbck.ne.0.or.minfwd.ne.0.or.recwin.ne.0)then

            write(*,502)'Start minute relative to nominal time ',minbck
 502        format(3x,a,i4)
            write(*,502)'End minute relative to nominal time   ',minfwd

            CALL MSETWIN(minbck,minfwd,recwin,istatus)
            if(istatus.ne.success_p)stop

         endif

      else

         write(*,500)'ACARSPDUMP: INVALID WINDOW RECORD TYPE'
         stop

      endif

C     Select a horizontal domain
C     --------------------------
C
C     The horizontal domain can be limited to match one of two map
C     projections (polar stereographic, Lambert conformal conic) or it
C     can be limited to a latitude/longitude rectangle.  Only stations
C     within the domain will be returned.  If one of the map projections
C     is selected, any winds (of any form) returned by subsequent
C     MGETACARSP calls will be rotated to match the projection.  See
C     msetdom.txt in the doc directory for an explanation of the 
C     parameters needed to define the domains.
C
C     If MSETDOM is not called, all available stations will be
C     returned, regardless of their location.
C
C     The example given here is for the CONUS 212 Lambert conformal 
C     conic projection.  
C
C     CALL MSETDOM(3,40635.25,12.19,-133.459,-95.0,25.0,25.0,dummy,
C    1             185,129,istatus)

C     PAR FILE INPUT:  Domain Filter (0 - don't filter, 
C                                     1 - lat/lon corners,
C                                     2 - Polar Stereographic grid,
C                                     3 - Lambert Conformal Conic grid)
      do i = 1, 7
         line = line + 1
         read(2,*,err=825,end=850)
      enddo

      line = line + 1
      read(2,*,err=825,end=850)idmtyp

C     We'll read in the parameters appropriate for the selected
C     domain filter, and skip over all of the other lines in the
C     rest of this section of the parameter file.

      write(*,501)'Domain Filter'

      if(idmtyp.eq.1)then

         do i = 1, 6
            line = line + 1
            read(2,*,err=825,end=850)
         enddo
         do i = 1, 4
            line = line + 1
            read(2,*,err=825,end=850)rpar(i)
         enddo
         do i = 1, 23
            line = line + 1
            read(2,*,err=825,end=850)
         enddo

         write(*,401)'Latitude/Longitude Corners'
         write(*,402)'SW corner latitude (north)                 ',
     1               rpar(1)
 402     format(3x,a,f13.6)
         write(*,402)'SW corner longitude (east)                 ',
     1               rpar(2)
         write(*,402)'NE corner latitude (north)                 ',
     1               rpar(3)
         write(*,402)'NE corner longitude (east)                 ',
     1               rpar(4)

         CALL MSETDOM(idmtyp,rpar(1),rpar(2),rpar(3),rpar(4),dummy,
     1                dummy,dummy,idummy,idummy,istatus)

      else if(idmtyp.eq.2)then

         do i = 1, 13
            line = line + 1
            read(2,*,err=825,end=850)
         enddo
         do i = 1, 7
            line = line + 1
            read(2,*,err=825,end=850)rpar(i)
         enddo
         do i = 1, 2
            line = line + 1
            read(2,*,err=825,end=850)ipar(i)
         enddo
         do i = 1, 11
            line = line + 1
            read(2,*,err=825,end=850)
         enddo

         write(*,401)'Polar Stereographic Grid'
         write(*,402)'Grid box size (meters)                     ',
     1               rpar(1)
         write(*,402)'Latitude (north) of 1st grid point         ',
     1               rpar(2)
         write(*,402)'Longitude (east) of 1st grid point         ',
     1               rpar(3)
         write(*,402)'Orientation longitude (east)               ',
     1               rpar(4)
         write(*,402)'I-coordinate of pole                       ',
     1               rpar(5)
         write(*,402)'J-coordinate of pole                       ',
     1               rpar(6)
         write(*,402)'Latitude (north) at which X-Y scale is true',
     1               rpar(7)
         write(*,403)'Number of grid points (X)                  ',
     1               ipar(1)
         write(*,403)'Number of grid points (Y)                  ',
     1               ipar(2)
 403     format(3x,a,i6)   

         CALL MSETDOM(idmtyp,rpar(1),rpar(2),rpar(3),rpar(4),rpar(5),
     1                rpar(6),rpar(7),ipar(1),ipar(2),istatus)

      else if(idmtyp.eq.3)then

         do i = 1, 25
            line = line + 1
            read(2,*,err=825,end=850)
         enddo
         do i = 1, 6
            line = line + 1
            read(2,*,err=825,end=850)rpar(i)
         enddo
         do i = 1, 2
            line = line + 1
            read(2,*,err=825,end=850)ipar(i)
         enddo

         write(*,401)'Lambert Conformal Conic Grid'
         write(*,402)'Grid box size (meters)                     ',
     1               rpar(1)
         write(*,402)'Latitude (north) of 1st grid point         ',
     1               rpar(2)
         write(*,402)'Longitude (east) of 1st grid point         ',
     1               rpar(3)
         write(*,402)'Orientation longitude (east)               ',
     1               rpar(4)
         write(*,402)'Latitude (north) of 1st tangent            ',
     1               rpar(5)
         write(*,402)'Latitude (north) of 2nd tangent            ',
     1               rpar(6)
         write(*,403)'Number of grid points (X)                  ',
     1               ipar(1)
         write(*,403)'Number of grid points (Y)                  ',
     1               ipar(2)

         CALL MSETDOM(idmtyp,rpar(1),rpar(2),rpar(3),rpar(4),rpar(5),
     1                rpar(6),dummy,ipar(1),ipar(2),istatus)

      else if(idmtyp.eq.0)then

         write(*,401)'No Filter'

         do i = 1, 33
            line = line + 1
            read(2,*,err=825,end=850)
         enddo
         
      else

         write(*,500)'ACARSPDUMP: INVALID DOMAIN TYPE'
         stop

      endif
      if(istatus.ne.success_p)stop

C     Select QC level of data to be returned
C     --------------------------------------
C
C     The primary variables in all MADIS datasets have been screened
C     by automated quality control (QC) checks.  Different variables
C     have different levels of QC, or "stages", applied to them.
C     For example, temperature may have level 1 checks (validity) and
C     level 2 checks (temporal consistency).  Note that each level of 
C     QC incorporates the previous levels, i.e., an ob that has passed 
C     level 2 has also passed any applicable level 1 checks.  See 
C     acarsp_qc_variable_list.txt in the doc directory for more 
C     information.
C
C     Each call to MGETACARSP will return obs and associated QC
C     information.  If the user doesn't want to interpret the QC info,
C     he or she can limit the returned obs to selectable levels of
C     quality.  In that case, obs that don't meet the selected QC level
C     will be replaced with missing data flags, and the QC information
C     itself doesn't need to be examined by the calling program.
C
C     If MSETQC is not called, all obs will be returned (along with QC
C     info).
C
C     There are three ways that the user can request and process the QC 
C     information:
C
C     1) Don't call MSETQC at all, and examine the QC info before
C        deciding whether or not to use each observation.  This
C        allows the calling program the maximum amount of control
C        over what's available.
C
C     2) If you know ahead of time that the same level of QC is
C        available for all variables you'll be using, call MSETQC
C        one time to select the desired QC level.  Note that the
C        level selected by MSETQC will stay in effect until the
C        next time MSETQC is called.
C
C     3) To require that all variables pass the highest level
C        of QC that are specified for them, call MSETQC one time
C        and select QC level 99.
C
C     User's of MADIS data who want the data filtered by QC results,
C     but don't want to interpret the QC information themselves, should
C     call MSETQC one time and select QC level 99.

C     PAR FILE INPUT:  QC level (0-none, 1-coarse, 2-screened, 
C                                99-highest possible)
      do i = 1, 3
         line = line + 1
         read(2,*,err=825,end=850)
      enddo
      line = line + 1
      read(2,*,err=825,end=850)qctyp

      write(*,501)'QC Filter'
      if(qctyp.ge.0.and.qctyp.le.3)then
         write(*,401)qcstr(qctyp)
      else if(qctyp.eq.99)then
         write(*,401)'Highest Possible'
      else
         write(*,500)'ACARSPDUMP: INVALID QC TYPE'
         stop
      endif

C     Select the QC level to be returned.

      CALL MSETQC(qctyp,istatus)
      if(istatus.ne.success_p)stop

C-----------------------------------------------------------------------
C SELECT NOMINAL TIME OF DATA TO BE RETURNED 
C ------------------------------------------
C
C     The MADIS library's native time zone and format is Universal 
C     Coordinated Time, using a Julian date, in the form of "YYJJJHHMM",
C     where:
C
C     YY  = 2-digit year (good from 1980 - 2179)
C     JJJ = Julian date of the year (001-366)
C     HH  = Hour (00-23)
C     MM  = Minute (00-59)
C
C     MADIS also provides support for a "Month/Day" date format, using
C     "YYYYMMDD_HHMM", where:
C
C     YYYY = 4-digit year (still only good from 1980 - 2179)
C     MMDD = Month/Day 
C     HHMM = Hour/Minute 
C
C     The MADIS library includes a basic set of routines that the caller
C     can use to:
C
C     - Add & subtract time in the native format.  (MCHGTIM)
C     - Translate the native format to integers representing year, 
C       month, day, hour, and minute.  (MINTTIM)
C     - Translate integers representing year, month, day, hour and
C       minute into the native format.  (MCHRTIM)
C     - Translate between Julian and Month/Day formats (MTRNTIM)
C
C     See time_routines.txt in the doc directory for details on how 
C     to use these calls.
C
C     Also note that nominal times can be specified at any minute, not
C     just at the top of the hour (minute 00).

C     PAR FILE INPUT:  Time format to use (0 - Julian, 1 - Month/Day)
      
      write(*,501)'Nominal Time'

      do i = 1, 6
         line = line + 1
         read(2,*,err=825,end=850)
      enddo
      line = line + 1
      read(2,*,err=825,end=850)tform
      if(tform.ne.0.and.tform.ne.1)then
         write(*,500)'ACARSPDUMP: INVALID TIME TRANSLATION FORMAT'
         stop
      endif

C     PAR FILE INPUT:  Nominal time (0 - specified in par file,
C                                    1 - use current time)
      line = line + 1
      read(2,*,err=825,end=850)
      line = line + 1
      read(2,*,err=825,end=850)ctime
      line = line + 1
      read(2,*,err=825,end=850)

C     PAR FILE INPUT:  Nominal time (in selected format)

      line = line + 1
      read(2,145,err=825,end=850)tstr

C     If the user wants to use the current time, get it and translate 
C     that into the chosen format (via our internal formats).  
C     Otherwise we have the chosen format in TSTR right now.

      if(ctime.eq.1)then
         i = TIME()
         i = i - 1325376000
         CALL M_MKFNAM(i,atime,istatus)
         if(tform.eq.1)then
            CALL MTRNTIM(atime,2,tstr,istatus)
         else
            tstr = atime
         endif
      endif

      if(tform.eq.1)then
         CALL MTRNTIM(tstr,1,atime,istatus)
         if(istatus.ne.success_p)stop
      else
         atime = tstr
      endif

      write(*,401)tstr

C     For most purposes, you'll want to read data for all stations
C     that meet the criteria already specified above.  For dump program
C     purposes, however, we offer the option to only get one station.

      write(*,501)'Station Selection'

C     PAR FILE INPUT:  Station Selection (0 - all stations, 1 - single)

      do i = 1, 3
         line = line + 1
         read(2,*,err=825,end=850)
      enddo

      line = line + 1
      read(2,*,err=825,end=850)ising
      line = line + 1
      read(2,*,err=825,end=850)
      line = line + 1
      read(2,145,err=825,end=850)singsta
      
      if(ising.eq.1)then
         write(*,401)singsta
      else
         write(*,401)'All stations'
      endif

      do i = 1, 3
         line = line + 1
         read(2,*,err=825,end=850)
      enddo

C-----------------------------------------------------------------------
C LOAD IN STATION INFO FOR SELECTED DATA
C --------------------------------------
C
C     Load in the stations covering the selected domain.  The MACARSPSTA
C     call needs to be done as the first call when getting data for a
C     new time, or whenever any of the optional setup calls are used.
C     Thereafter, MGETACARSP and MGETACARSPC can be called as many times 
C     as desired in order to read variables.

      CALL MACARSPSTA(atime,nsta,stanam,wmoid,lat,lon,elev,timeob,
     1                istatus)
      if(istatus.ne.success_p)stop

C     If one of the map projections has been selected for the horizontal
C     domain, the station latitude and longitude can be converted to a 
C     floating point grid index into the 2-dimensional grid (RI,RJ).  
C     Note that this works for grids laid out this way:
C
C                        NE (I=NX,J=NY)
C
C     SW (I=1,J=1)
C
C     If we're to convert LAT/LON to RI,RJ for the user's grid, do
C     so.  Otherwise, fill in 0's so there'll be something in the
C     output line that isn't too messy.

      if(idmtyp.eq.2.or.idmtyp.eq.3)then

         do i = 1, nsta
            CALL MGETIJ(lat(i),lon(i),ri(i),rj(i),istatus)
         enddo
         
      else

         do i = 1, nsta
            ri(i) = 0
            rj(i) = 0
         enddo

      endif

C-----------------------------------------------------------------------
C LOOP THROUGH DESIRED VARIABLES:
C -------------------------------
C
C     Variables are specified by code names.  The list of code names
C     can be found in the first column of acarsp_variable_list.txt in 
C     the doc directory.  
C
C     This program will read in up to 4 variable codes per line in the
C     parameter file, read them, output them, then move on to the next
C     set of variables until the end of the parameter file is reached.

      write(*,501)'Variables'

C     PAR FILE INPUT:  1 to 4 variable codes (free-formatted)

 100  read(2,145,end=900)vline

C     Parse the line to determine the number of variables and their
C     code names (1 to 4 code names separated by spaces).

      nvar = 0
      l = -1
      do i =  1, 4
         j = l
         CALL M_FINDWORD(vline,70,j,k,l)
         if(k.eq.0)then
            go to 101
         else
            nvar = nvar + 1
            vcode(nvar) = vline(k:l)
         endif
      enddo

 101  if(nvar.eq.0) go to 100

C     Use internal MADIS routines (MGETVCN, MGENVCN) to translate the 
C     variable code name into the MADIS variable code number, and to
C     determine the type (numeric or character) of the variable.  The
C     code number is also then used to determine the profile type.  
C     This is needed here because this program is an all-purpose utility
C     meant to handle any desired profile type.  In general, a user's 
C     MADIS program shouldn't have to determine the profile type (as you 
C     would know what variables you're reading).

C        Profile Type
C        -------------------
C       -20       Profile data
C        0        Single-dimensioned (not a profile)
     
      do i = 1, nvar
         CALL MGETVCN(vcode(i),vcn,vtype(i),istatus)
         if(istatus.ne.success_p)stop
         CALL MGENVCN(vcn,acarsp_ds_p,idb,dummy,profile_type(i))
      enddo

C     Make sure the user didn't select a mismatch by mixing variables
C     with different profile or data types on the same input line.  
C     (This is against the rules in this program because we're expecting
C     the same number of levels for all variables output on the same
C     line -- one output line per level will result.)

      j = profile_type(1)
      c = vtype(1)
      do i = 2, nvar
         if(profile_type(i).ne.j.or.vtype(i).ne.c)then
            write(*,519)'Variable/profile type mismatch: ',
     1                  (vcode(k),k=1,nvar)
 519        format(1x,a,4(1x,a))
            go to 100
         endif
      enddo

      do 150 i = 1, nvar

         write(*,505)vcode(i)
 505     format(3x,'Processing',5x,a)

C     Read the desired variables and QC info.  The returned arrays
C     will match the records in the station info arrays returned
C     from MACARSPSTA.  If a QC level has been selected, the obs will
C     only be returned if they meet or exceed the selected QC
C     level.

         if(vtype(1).eq.'N')then

            if(profile_type(1).eq.-20)then

C     The MGETACARSP routine is used to read all numeric variables.
C     All variables are returned as Fortran REAL type (RDATA200), the
C     QC data descriptors are always CHARACTER*1 (QCD200), and the
C     bit masks showing the QC checks that were applied (QCA200) and
C     their results (QCR200) are always INTEGER.

               CALL MGETACARSP(atime,vcode(i),nsta,nobs,nlevels,
     1                         rdata200(1,1,i),qcd200(1,1,i),
     2                         qca200(1,1,i),qcr200(1,1,i),istatus)

            else if(profile_type(1).eq.0)then

               CALL MGETACARSP(atime,vcode(i),nsta,nobs,nlevels,
     1                         rdata1(1,i),qcd1(1,i),qca1(1,i),
     2                         qcr1(1,i),istatus)

            endif

            write(1,146)'var ',vcode(i),' total stns ',nsta,
     1                  ' # non-missing obs ',nobs
 146        format(/,1x,a,a,a,i5,a,i5)

            if(istatus.ne.success_p)go to 150

C     Put the variable code name into an array that will be used as
C     a label in header lines in the output file.

            vcstr(i) = vcode(i)//' QCD  QCA  QCR'

         else if(vtype(1).eq.'C')then

C     The MGETACARSPC routine is used to read character variables.  No 
C     QC is currently available for any of these variables.  Note that
C     there are no missing data flags for character data, and therefore
C     no equivalent of the NOBS argument returned from MGETACARSP;
C     instead, blanks are filled in where no genuine data exist.

            if(vcode(i).eq.'STALOC ')then

               CALL MGETACARSPC(atime,vcode(i),nsta,staloc,istatus)

            else if(vcode(i).eq.'TAILNUM'.and.db(1:3).eq.'FSL')then

               CALL MGETACARSPC(atime,vcode(i),nsta,tailnum,istatus)

            else if(vcode(i).eq.'TAILNUM'.and.db(1:5).eq.'AWIPS')then

               CALL MGETACARSPC(atime,vcode(i),nsta,atailnum,istatus)

            else if(vcode(i).eq.'FLNUM  ')then

               CALL MGETACARSPC(atime,vcode(i),nsta,flnum,istatus)

            endif

            write(1,146)'var ',vcode(i),' total stns ',nsta

            if(istatus.ne.success_p)go to 150

            vcstr(i) = vcode(i)

         endif

 150  continue

C     Output the station info, variables and QC.

      write(1,*)

      do 200 i = 1, nsta

C     If we're getting only one station, make sure this is it.

         if(ising.eq.1.and.singsta.ne.stanam(i))go to 200

C     Use the time output format desired by the user.

         if(tform.eq.0)then

            tstr = '  '//timeob(i)

         else if(tform.eq.1)then

            CALL MTRNTIM(timeob(i),2,tstr,istatus)

         endif

         if(vtype(1).eq.'N')then

            if(nlevels(i).ne.0)
     1           write(1,1000)stanam(i),wmoid(i),elev(i),lat(i),lon(i),
     2                        ri(i),rj(i),nlevels(i),tstr,
     3                        (vcstr(j),j=1,nvar)
 1000       format(1x,'Station     WMOID  Elev(m)   Lat(N)  Lon(E)  ',
     1             'Grid I   Grid J  NumLev    ObTime',/,
     3             1x,a,1x,i6,1x,f9.2,1x,f6.2,1x,f7.2,1x,
     4             2(f8.3,1x),2x,i3,3x,a,/,/,1x,'Level   ',4(a,5x))

            do j = 1, nlevels(i)

               if(profile_type(1).eq.-20.and.nlevels(i).ne.1)then

                  write(1,2000)j,(rdata200(j,i,k),qcd200(j,i,k),
     1                         qca200(j,i,k),qcr200(j,i,k),k=1,nvar)
 2000             format(1x,i3,4(1x,f13.6,1x,a,1x,i4,1x,i4))

               else if(profile_type(1).eq.0)then

                  write(1,2000)j,(rdata1(i,k),qcd1(i,k),
     1                         qca1(i,k),qcr1(i,k),k=1,nvar)

               endif

            enddo

            if(i.ne.nsta.and.nlevels(i).ne.0)write(1,*)

         else if(vtype(1).eq.'C')then

C     Because there are different sizes of character variables, we have
C     to build up the output line in memory, then output it after
C     going through all NVAR variables.

            write(1,1000)stanam(i),wmoid(i),elev(i),lat(i),lon(i),ri(i),
     1                   rj(i),1,tstr,(vcstr(k),k=1,nvar)
            k = 10
            oline = '   1     '

            do j = 1, nvar

               if(vcode(j).eq.'STALOC ')then

                  write(oline(k:k+50),145)staloc(i)
                  k = k + 51

               else if(vcode(j).eq.'TAILNUM'.and.db(1:3).eq.'FSL')then

                  write(oline(k:k+11),145)tailnum(i)
                  k = k + 12

               else if(vcode(j).eq.'TAILNUM'.and.db(1:5).eq.'AWIPS')then

                  write(oline(k:k+8),145)atailnum(i)
                  k = k + 9

               else if(vcode(j).eq.'FLNUM  ')then

                  write(oline(k:k+12),145)flnum(i)
                  k = k + 13

               endif

            enddo

            write(1,145)oline(1:k-1)
            if(i.ne.nsta)write(1,*)

         endif

 200  continue

C     Process the next line of variables.

      go to 100

C-----------------------------------------------------------------------
C PROGRAM EXIT
C ------------
C
C     Error exits.

 825  write(*,503)'ACARSPDUMP: READ ERROR IN PARAMETER FILE AT LINE ',
     1            line
 503  format(1x,a,i4)
      stop

 850  write(*,500)'ACARSPDUMP: PREMATURE END OF PARAMETER FILE'

C     Normal exit.

 900  stop
      end
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
