C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    M_PHTINT    INTERPOLATE MISSING RAOB P & HT
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 00-02-10
C
C ABSTRACT: INTERPOLATE MISSING P & HT RAOB VARIABLES WHERE POSSIBLE.
C
C PROGRAM HISTORY LOG:
C   00-02-10  M. BARTH    ORIGINAL VERSION
C   08-06-13  L. BENJAMIN CHANGED "MADISCON" INCLUDE TO 
C                         "INTQC1CON1".  
C
C USAGE:    CALL M_PHTINT (NDLEV,NDSTA,NRECS,NLEVELS,PROC_STA,LTYPE,T,P,
C                          HT,PHTYPE)
C
C   INPUT ARGUMENT LIST:
C     NDLEV    - I       SIZE TO USE FOR LEVEL DIMENSION IN ARRAYS
C     NDSTA    - I       SIZE TO USE FOR STATION DIMENSION IN ARRAYS
C     NRECS    - I       NUMBER OF OB RECORDS READ
C     NLEVELS  - IA      NUMBER OF LEVELS
C     PROC_STA - LA      WHETHER OR NOT TO PROCESS EACH STATION
C     LTYPE    - IA      LEVEL TYPES (E.G., MANDATORY, SIGT)
C     T        - RA      TEMPERATURES
C
C   INPUT/OUTPUT ARGUMENT LIST:
C     P        - RA      PRESSURES
C     HT       - RA      HEIGHTS
C
C   OUTPUT ARGUMENT LIST:
C     PHTYPE   - IA      P/H TYPE:  0-INPUT, 1-P INTERP, 2-H INTERP
C
C SUBPROGRAMS CALLED:
C     UNIQUE:  M_INTHT, M_INTP, M_LOGHT
C
C
C REMARKS:
C     THE INTERPOLATION ALGORITHM USED IS FROM THE FSL RADIOSONDE
C     DATABASE PROJECT.
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE M_PHTINT(NDLEV,NDSTA,NRECS,NLEVELS,PROC_STA,LTYPE,T,P,
     1                    HT,PHTYPE)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'INTQC1CON1'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER NDLEV,NDSTA,NRECS
      INTEGER NLEVELS(NDSTA)
      LOGICAL PROC_STA(NDSTA)
      INTEGER LTYPE(NDLEV,NDSTA)
      REAL T(NDLEV,NDSTA)
      REAL P(NDLEV,NDSTA)
      REAL HT(NDLEV,NDSTA)
      INTEGER PHTYPE(NDLEV,NDSTA)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J


C     *****************************************************************
C     ******************* BEGIN OF M_PHTINT ***************************
C     *****************************************************************

      DO 1 J = 1, NRECS

         IF(NLEVELS(J).NE.MISS_P.AND.PROC_STA(J))THEN

            DO 100 I = 1, NLEVELS(J)

               PHTYPE(I,J) = 0

               IF((P(I,J).EQ.MISS_P).AND.(HT(I,J).NE.MISS_P))THEN

                  CALL M_INTP(I,NLEVELS(J),LTYPE(1,J),HT(1,J),P(1,J))
                  IF(P(I,J).NE.MISS_P)PHTYPE(I,J) = 1

               ENDIF

               IF((HT(I,J).EQ.MISS_P).AND.(P(I,J).NE.MISS_P))THEN

                  IF(T(I,J).EQ.MISS_P)THEN

                     CALL M_LOGHT(I,NLEVELS(J),LTYPE(1,J),P(1,J),
     1                            HT(1,J))

                  ELSE

                     CALL M_INTHT(I,NLEVELS(J),P(1,J),T(1,J),HT(1,J))

                  ENDIF

                  IF(HT(I,J).NE.MISS_P)PHTYPE(I,J) = 2

               ENDIF

 100        CONTINUE

         ENDIF

 1    CONTINUE

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
