C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MNPNBEAM    GET NPN BEAM-DIMENSIONED VARIABLE
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 00-03-27
C
C ABSTRACT: GET NPN VARIABLE THAT'S DIMENSIONED BY ANTENNA BEAM FROM
C   ONE FILE FOR ONE TIME.
C
C PROGRAM HISTORY LOG:
C   00-03-27  M. BARTH    ORIGINAL VERSION
C   01-05-03  M. BARTH    CHANGED MRDNUM/MRDCHR TO MGTNUM/MGTCHR
C   02-05-29  M. BARTH    RESTRUCTURED TEMPORARY MEMORY ARRAY USAGE
C   04-10-16  L. BENJAMIN ADDED NO SUCH VARIABLE CHECK FOR QCA CHECKS
C
C USAGE:    CALL MNPNBEAM (VCN,DSN,FNUM,NVDIMS,OB,QCDESC,QCAPP,QCRES,
C                          STATUS)
C
C   INPUT ARGUMENT LIST:
C     VCN      - I       VARIABLE CODE NUMBER 
C     DSN      - I       DATASET CODE NUMBER
C     FNUM     - I       FILE NUMBER (INDEX IN COMMON) OF NETCDF FILE
C     NVDIMS   - I       NUMBER OF DIMENSIONS FOR THE VARIABLE
C
C   OUTPUT ARGUMENT LIST:
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - RA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - RA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     NETCDF FILE OPENED USING DATA STRUCTURES FOR FNUM IN STRCCOM
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MGTCHR, MGTNUM
C
C REMARKS:
C   - "BEAM-DIMENSIONED" VARIABLES CAN ONLY BE REQUESTED FOR ONE
C     ANTENNA BEAM AT A TIME.  THIS IS DONE WITH THE VCN'S AVAILABLE
C     FOR THESE NPN VARIABLES.
C   - AT THE INITIAL WRITING, QC INFORMATION DOESN'T EXIST FOR
C     THESE VARIABLES, BUT IS HANDLED HERE IN THE CODE AS IF IT
C     WERE TO SIMPLIFY ADDING THIS FEATURE (IF DESIRED) LATER.
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MNPNBEAM (VCN,DSN,FNUM,NVDIMS,OB,QCDESC,QCAPP,QCRES,
     1                     STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER VCN,DSN,FNUM,NVDIMS,STATUS
      REAL OB(*),QCAPP(*),QCRES(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,L,LEN1REC,CD

      REAL OBTMP2(3,MXNPN_P)
      REAL QCATMP2(3,MXNPN_P),QCRTMP2(3,MXNPN_P)
      CHARACTER*1 QCDTMP2(3,MXNPN_P)

      REAL OBTMP3(3,MXNPNLEV_P,MXNPN_P)
      REAL QCATMP3(3,MXNPNLEV_P,MXNPN_P),QCRTMP3(3,MXNPNLEV_P,MXNPN_P)
      CHARACTER*1 QCDTMP3(3,MXNPNLEV_P,MXNPN_P)

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(OBTMP2,OBTMP3,TMP_L2_N1)
      EQUIVALENCE(QCATMP2,QCATMP3,TMP_L2_N2)
      EQUIVALENCE(QCRTMP2,QCRTMP3,TMP_L2_N3)
      EQUIVALENCE(QCDTMP2,QCDTMP3,TMP_L2_C1)

C     ------------------------------------------------------------------
C     READ IN THE VARIABLE & ANY ASSOCIATED QC INFO INTO LOCAL ARRAYS.
C     ------------------------------------------------------------------
      CD = DSN - MAX_SFCDSET_P

      CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),UAPT_NCID(FNUM,CD),
     1            UAPT_RECDIM(FNUM,CD),1,UAPT_NRECS(FNUM,CD),MISS_P,
     2            OBTMP3,STATUS)
      IF(STATUS.NE.SUCCESS_P)RETURN

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
      QCSTATUS = EQCOK_P

      IF(VQC(VCN,DSN).EQ.'Q')THEN

         CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCA',
     1               UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     2               UAPT_NRECS(FNUM,CD),MISS_P,QCATMP3,STATUS)
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            QCSTATUS = EQCFAILED_P
            STATUS = SUCCESS_P
            IF(NVDIMS.EQ.2)THEN

               DO I = 1, UAPT_NRECS(FNUM,CD)
                  DO J = 1, 3
                     QCATMP2(J,I) = 0
                     QCRTMP2(J,I) = 0
                     QCDTMP2(J,I) = 'Z'
                  ENDDO
               ENDDO
               
            ELSE

               DO I = 1, UAPT_NRECS(FNUM,CD)
                  DO J = 1, MXNPNLEV_P
                     DO K = 1, 3
                        QCATMP3(K,J,I) = 0
                        QCRTMP3(K,J,I) = 0
                        QCDTMP3(K,J,I) = 'Z'
                     ENDDO
                  ENDDO
               ENDDO
         ENDIF
         ELSE IF(STATUS.NE.SUCCESS_P)THEN
            RETURN
         ELSE
            CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCR',
     1               UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     2               UAPT_NRECS(FNUM,CD),MISS_P,QCRTMP3,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN

            CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'DD',
     1               UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     2               UAPT_NRECS(FNUM,CD),QCDTMP3,LEN1REC,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN
         ENDIF
      ELSE
         QCSTATUS = EQCFAILED_P

         IF(NVDIMS.EQ.2)THEN

            DO 1 I = 1, UAPT_NRECS(FNUM,CD)
               DO 2 J = 1, 3
                  QCATMP2(J,I) = 0
                  QCRTMP2(J,I) = 0
                  QCDTMP2(J,I) = 'Z'
 2             CONTINUE
 1          CONTINUE

         ELSE

            DO 3 I = 1, UAPT_NRECS(FNUM,CD)
               DO 4 J = 1, MXNPNLEV_P
                  DO 5 K = 1, 3
                     QCATMP3(K,J,I) = 0
                     QCRTMP3(K,J,I) = 0
                     QCDTMP3(K,J,I) = 'Z'
 5                CONTINUE
 4             CONTINUE
 3          CONTINUE

         ENDIF

      ENDIF


C     ------------------------------------------------------------------
C     DETERMINE WHICH BEAM NUMBER THE CALLER WANTS, THEN RETURN THE
C     DATA IN HIS ARRAYS AND RETURN.
C     ------------------------------------------------------------------
      IF(NVDIMS.EQ.2)THEN

         IF(VCN.EQ.NPNABA_N_VN_P.OR.VCN.EQ.NPNABE_N_VN_P)THEN
            K = 1
         ELSE IF(VCN.EQ.NPNABA_E_VN_P.OR.VCN.EQ.NPNABE_E_VN_P)THEN
            K = 2
         ELSE
            K = 3
         ENDIF

         DO 11 I = 1, UAPT_NRECS(FNUM,CD)

            OB(I) = OBTMP2(K,I)
            QCAPP(I) = QCATMP2(K,I)
            QCRES(I) = QCRTMP2(K,I)
            QCDESC(I) = QCDTMP2(K,I)

 11      CONTINUE

      ELSE IF(NVDIMS.EQ.3)THEN

         IF(VCN.EQ.NPNCNUM_N_VN_P.OR.VCN.EQ.NPNPP_N_VN_P.OR.
     1      VCN.EQ.NPNRV_N_VN_P.OR.VCN.EQ.NPNSW_N_VN_P)THEN
            K = 1
         ELSE IF(VCN.EQ.NPNCNUM_E_VN_P.OR.VCN.EQ.NPNPP_E_VN_P.OR.
     1           VCN.EQ.NPNRV_E_VN_P.OR.VCN.EQ.NPNSW_E_VN_P)THEN
            K = 2
         ELSE
            K = 3
         ENDIF

         L = 1

         DO 12 I = 1, UAPT_NRECS(FNUM,CD)

            DO 13 J = 1, MXNPNLEV_P

               OB(L) = OBTMP3(K,J,I)
               QCAPP(L) = QCATMP3(K,J,I)
               QCRES(L) = QCRTMP3(K,J,I)
               QCDESC(L) = QCDTMP3(K,J,I)
               L = L + 1

 13         CONTINUE

 12      CONTINUE

      ENDIF

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
