C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MGETHYDRO   GET HYDRO OBS & QC INFO FOR ONE VARIABLE
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 01-07-24
C
C ABSTRACT: READ HYDRO OBS & QC INFO FOR ALL STATIONS FOR ONE VARIABLE
C   AND TIME.
C
C PROGRAM HISTORY LOG:
C   01-07-24  M. BARTH    ORIGINAL VERSION
C   02-05-29  M. BARTH    RESTRUCTURED TEMPORARY MEMORY ARRAY USAGE
C   03-09-25  M. BARTH    SET MADISCOM CDTYPE VARIABLE FOR THIS DATA
C                         TYPE -- NO HARM WAS CAUSED BY NOT DOING THIS,
C                         BUT THIS NEEDS TO BE CONSISTENT ACROSS DATA
C                         TYPES TO ALLOW FULL FLEXIBILITY WHEN ADDING
C                         FEATURES.
C   04-10-16  L.BENJAMIN  ADDED NO SUCH VARIABLE CHECK FOR QCA CHECKS
C
C USAGE:    CALL MGETHYDRO (ATIME,VCODE,NSTA,NOBS,OB,QCDESC,QCAPP,QCRES,
C                           STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C     VCODE    - C       VARIABLE CODE NAME
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     NOBS     - I       NUMBER OF NON-MISSING OBS (<= NSTA)
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - IA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - IA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS HYDRO NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, MGETVCN, MGTNUM, MGTCHR, MQCFLTR
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT AND MHYDROSTA BEFORE CALLING THIS
C     ROUTINE.  MHYDROSTA SHOULD BE CALLED FIRST WHENEVER ACCESS TO
C     A NEW TIME IS DESIRED.  IT STORES INFO IN THE STRCCOM COMMON
C     THAT IS USED BY THIS ROUTINE TO FIGURE OUT WHICH RECORDS ARE
C     NEEDED ON NETCDF FILES OPENED BY MHYDROSTA.
C   - DOUBLE & CHARACTER DATA TYPES ARE NOT HANDLED BY THIS ROUTINE.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXHYDRO_P IN
C     madiscon.f.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MGETHYDRO(ATIME,VCODE,NSTA,NOBS,OB,QCDESC,QCAPP,QCRES,
     1                     STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME
      CHARACTER*(*) VCODE
      INTEGER NSTA,NOBS,QCAPP(*),QCRES(*),STATUS
      REAL OB(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,FNUM,DSN,LEN1REC,DUMMY,VCN
      REAL OBTMP(MXHYDRO_P),QCATMP(MXHYDRO_P),QCRTMP(MXHYDRO_P),FACTOR
      CHARACTER*1 QCDTMP(MXHYDRO_P),VCT
      LOGICAL PROC_FILE(HYDRO_MXSTRF)

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(OBTMP,TMP_L1_N1)
      EQUIVALENCE(QCATMP,TMP_L1_N2)
      EQUIVALENCE(QCRTMP,TMP_L1_N3)
      EQUIVALENCE(QCDTMP,TMP_L1_C1)

C     ------------------------------------------------------------------
C     IF THE HYDRO SUBSYSTEM HASN'T BEEN INITIALIZED, OR IF THE 
C     REQUESTED TIME DOESN'T MATCH THE TIME LAST PROCESSED BY MHYDROSTA,
C     OR IF THE VCODE IS CLEARLY ILLEGAL, RETURN WITH ERROR.
C     ------------------------------------------------------------------
      IF(HYDRO_INIT.NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MGETHYDRO: SELECTED SUBSYSTEM NOT INITIALIZED -'//
     1               ' HYDRO')
         GO TO 900
      ELSE IF(ATIME.NE.LAST_HYDRO_ATIME.OR.ATIME.EQ.'         ')THEN
         STATUS = TIME_NOTINIT_P
         CALL MERROR('MGETHYDRO: TIME NOT INITIALIZED BY MHYDROSTA')
         GO TO 900
      ELSE 
         CALL MGETVCN(VCODE,VCN,VCT,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900
      ENDIF

C     ------------------------------------------------------------------
C     SET THE CURRENT DATA TYPE.
C     ------------------------------------------------------------------
      CDTYPE = HYD_DS_P

C     ------------------------------------------------------------------
C     FILL IN MISSING FLAGS FOR ALL POSSIBLE RECORDS IN CALLER'S ARRAY,
C     INDICATE THAT WE HAVEN'T PROCESSED ANY FILES YET.
C     THEN LOOP THROUGH THE FILES THAT ARE NEEDED AND PUT IN REAL DATA
C     WHERE AVAILABLE.
C     ------------------------------------------------------------------
      NSTA = HYDRO_LNUM
      IF(NSTA.EQ.0)THEN
         STATUS = NO_DATA_P
         GO TO 900
      ENDIF

      FNUM = 0

      DO 1 I = 1, NSTA
         OB(I) = MISS_P
         OBTMP(I) = MISS_P
         QCDESC(I) = 'Z'
         QCAPP(I) = 0
         QCRES(I) = 0
 1    CONTINUE

      DO 2 I = 1, HYDRO_MXSTRF
         PROC_FILE(I) = .FALSE.
 2    CONTINUE

C     ------------------------------------------------------------------
C     NOTE THAT WE LOOP THROUGH HYDRO_FNUM TO SEE WHICH FILES ARE NEEDED
C     AND NOT THROUGH HYDRO_NFILES.  THIS IS DONE AS JUST BECAUSE A FILE
C     GOT READ DOESN'T MEAN ANY OF ITS RECORDS ACTUALLY WERE EXTRACTED
C     WHEN ALL THE FILTERING WAS DONE IN MHYDROSTA.  THEREFORE, WE'LL
C     ONLY PROCESS EACH FILE WITH RECORDS IN USE.
C     ------------------------------------------------------------------
      DO 100 I = 1, NSTA

C     ------------------------------------------------------------------
C     ALREADY HANDLED THIS FILE.
C     ------------------------------------------------------------------
         IF(PROC_FILE(HYDRO_FNUM(I)))GO TO 100

         FNUM = HYDRO_FNUM(I)
         PROC_FILE(FNUM) = .TRUE.
         DSN = MAX_SFCDSET_P + MAX_UAPTDSET_P + HYDRO_SOURCE(FNUM)

C     ------------------------------------------------------------------
C     THE VARIABLE'S NOT ASSOCIATED WITH THIS SOURCE DATASET.
C     ------------------------------------------------------------------
         IF(VLEN(VCN,DSN).EQ.0)GO TO 100

C     ------------------------------------------------------------------
C     THE VARIABLE'S DOUBLE OR CHARACTER DATA TYPE:  THIS WILL BE
C     TRUE FOR ANY DATASET FOR WHICH THIS VARIABLE APPLIES, AND IS
C     AN ILLEGAL OPTION.
C     ------------------------------------------------------------------
         IF(VDTYPE(VCN,DSN).EQ.'d'.OR.VDTYPE(VCN,DSN).EQ.'c')THEN
            STATUS = INV_DTYPE_P
            CALL MERROR('MGETHYDRO: INVALID VARIABLE DATA TYPE')
            GO TO 900
         ENDIF

C     ------------------------------------------------------------------
C     IF THE VARIABLE NEEDS TO BE CREATED FROM OTHER VARIABLES, CALL
C     A SUBROUTINE TO FILL IN THE LOCAL ARRAYS.  OTHERWISE, READ THE
C     VARIABLE, AND IF AVAILABLE, QC INFO.  IF THERE'S AN ERROR,
C     THE SUBROUTINES WILL HAVE SET STATUS & CALLED MERROR.
C
C     AT THE INITIAL WRITING, NO VARIABLES CALL FOR SPECIAL HANDLING.
C     ------------------------------------------------------------------
         CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),HYDRO_NCID(FNUM),
     1               HYDRO_RECDIM(FNUM),1,HYDRO_NRECS(FNUM),MISS_P,
     2               OBTMP,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
         QCSTATUS = EQCOK_P

         IF(VQC(VCN,DSN).EQ.'Q')THEN

            CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCA',
     1                  HYDRO_NCID(FNUM),HYDRO_RECDIM(FNUM),1,
     2                  HYDRO_NRECS(FNUM),MISS_P,QCATMP,STATUS)

            IF(STATUS.EQ.VAR_NOTINDB_P)THEN
               QCSTATUS = EQCFAILED_P
               STATUS = SUCCESS_P
               DO 11 J = 1, HYDRO_NRECS(FNUM)
                  
                  QCDTMP(J) = 'Z'
                  QCATMP(J) = 0
                  QCRTMP(J) = 0

 11               CONTINUE
            ELSE IF(STATUS.NE.SUCCESS_P)THEN
               GO TO 900
            ELSE
               CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCR',
     1                  HYDRO_NCID(FNUM),HYDRO_RECDIM(FNUM),1,
     2                  HYDRO_NRECS(FNUM),MISS_P,QCRTMP,STATUS)
               IF(STATUS.NE.SUCCESS_P)GO TO 900

               CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'DD',
     1                  HYDRO_NCID(FNUM),HYDRO_RECDIM(FNUM),1,
     2                  HYDRO_NRECS(FNUM),QCDTMP,LEN1REC,STATUS)
               IF(STATUS.NE.SUCCESS_P)GO TO 900               
            ENDIF
         ELSE
            QCSTATUS = EQCFAILED_P

            DO 10 J = 1, HYDRO_NRECS(FNUM)

               QCDTMP(J) = 'Z'
               QCATMP(J) = 0
               QCRTMP(J) = 0

 10         CONTINUE

         ENDIF

C     ------------------------------------------------------------------
C     DO ANY NECESSARY UNITS CONVERSIONS TO RETURN M/K/S UNITS.
C     - ACCUMULATED PRECIPS FROM MM TO M
C     ------------------------------------------------------------------
         FACTOR = 0.0
         IF(VCN.EQ.HYDPCP5M_VN_P.OR.VCN.EQ.HYDPCP1_VN_P.OR.
     1      VCN.EQ.HYDPCP3_VN_P.OR.VCN.EQ.HYDPCP6_VN_P.OR.
     2      VCN.EQ.HYDPCP12_VN_P.OR.VCN.EQ.HYDPCP24_VN_P)THEN
            FACTOR = 0.001
         ENDIF

         IF(FACTOR.NE.0.0)THEN

            DO 110 J = 1, HYDRO_NRECS(FNUM)
               IF(OBTMP(J).NE.MISS_P)OBTMP(J) = OBTMP(J) * FACTOR
 110        CONTINUE

         ENDIF

C     ------------------------------------------------------------------
C     DO ANY REQUESTED QC FILTERING.  NOTE THAT THIS IS DONE INSIDE THE
C     DO 100 LOOP SO THAT MQCFLTR CAN HANDLE EACH HYDRO DATASET
C     INDIVIDUALLY.  THIS IS NEEDED TO COVER THE CASE OF QC INFO NOT
C     BEING AVAILABLE FOR ALL HYDRO DATASETS, BUT IS AVAILABLE FOR SOME.
C     ------------------------------------------------------------------
         CALL MQCFLTR(VCN,DSN,HYDRO_NRECS(FNUM),1,QCDTMP,DUMMY,DUMMY,
     1                OBTMP)

C     ------------------------------------------------------------------
C     EXTRACT DESIRED RECORDS INTO CALLER'S ARRAY.
C     ------------------------------------------------------------------
         DO 120 J = I, NSTA

            IF(HYDRO_FNUM(J).NE.FNUM)GO TO 120

            OB(J) = OBTMP(HYDRO_RNUM(J))
            QCDESC(J) = QCDTMP(HYDRO_RNUM(J))
            QCAPP(J) = QCATMP(HYDRO_RNUM(J))
            QCRES(J) = QCRTMP(HYDRO_RNUM(J))

 120     CONTINUE

 100  CONTINUE

 900  IF(STATUS.NE.SUCCESS_P)THEN

         NSTA = 0
         NOBS = 0

      ELSE

C     ------------------------------------------------------------------
C     COUNT UP THE NUMBER OF NON-MISSING OBS ACTUALLY RETURNED.
C     ------------------------------------------------------------------
         NOBS = 0

         DO 121 J = 1, NSTA
            IF(OB(J).NE.MISS_P)NOBS = NOBS + 1
 121     CONTINUE

         IF(NOBS.EQ.0)THEN
            NSTA = 0
            STATUS = NO_DATA_P
         ENDIF

      ENDIF

      RETURN
      END

C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
