C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MGETRAOBC   GET RAOB CHARACTER DATA FOR ONE VARIABLE
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 00-04-11
C
C ABSTRACT: READ RAOB CHARACTER DATA FOR ALL STATIONS FOR ONE VARIABLE
C   AND TIME.
C
C PROGRAM HISTORY LOG:
C   00-04-11  M. BARTH    ORIGINAL VERSION
C   00-03-22  M. BARTH    CHANGES TO ALLOW FOR UPPER-AIR-POINT DATA
C   01-05-25  M. BARTH    FIXED A BUG WHERE WE WEREN'T USING THE RNUM
C                         SO ALWAYS RETURNED RECORDS 1-N REGARDLESS
C                         OF WHAT'S BEEN TIME OR DOMAIN FILTERED.
C   01-07-02  M. BARTH    - ADDED CDBTYPE
C                         - CHANGE FROM CALLER-SPECIFIED VARIABLE CODE
C                           NUMBER TO VARIABLE CODE NAME
C                         - RETURN VAR_NOTINDB_P ERROR IF AWIPS 
C                           DATABASE & VARIABLE IS RELEASE TIME --
C                           IT'S IN THE FILE, BUT IT'S BOGUS...
C
C USAGE:    CALL MGETRAOBC (ATIME,VCODE,NSTA,CDATA,STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C     VCODE    - C       VARIABLE CODE NAME
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     CDATA    - CA      ARRAY OF RETURNED CHARACTER DATA
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS RAOB NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, MGETVCN, MRDDBL, M_MKFNAM
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT AND MRAOBSTA BEFORE CALLING THIS
C     ROUTINE.  MRAOBSTA SHOULD BE CALLED FIRST WHENEVER ACCESS TO
C     A NEW TIME IS DESIRED.  IT STORES INFO IN THE STRCCOM COMMON
C     THAT IS USED BY THIS ROUTINE TO FIGURE OUT WHICH RECORDS ARE
C     NEEDED ON NETCDF FILES OPENED BY MRAOBSTA.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXRAOB_P IN
C     madiscon.f, AND TO MATCH THE DIMENSIONS OF THE LARGEST VERSION
C     OF THE VARIABLE IN ANY DATASET.  SEE THE MADIS USER'S GUIDE
C     TO SEE WHAT DIMENSIONS SHOULD BE USED FOR THE CHARACTER
C     VARIABLES.
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MGETRAOBC(ATIME,VCODE,NSTA,CDATA,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME
      CHARACTER*(*) VCODE
      INTEGER NSTA,STATUS
      CHARACTER*9 CDATA(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,FNUM,DSN,CD,RTIME,VCN
      DOUBLE PRECISION DTIME(MXRAOB_P*4)
      LOGICAL HAVE_ANY
      CHARACTER*1 VCT

C     ------------------------------------------------------------------
C     SET THE CURRENT DATASET TYPE TO RAOB.
C     ------------------------------------------------------------------
      CDTYPE = RAOB_DS_P
      CD = RAOB_DS_P
      CDBTYPE = UAPT_DBTYPE(CD)
      DSN = MAX_SFCDSET_P + CD
      HAVE_ANY = .FALSE.

C     ------------------------------------------------------------------
C     IF THE RAOB SUBSYSTEM HASN'T BEEN INITIALIZED, OR IF THE REQUESTED
C     TIME DOESN'T MATCH THE TIME LAST PROCESSED BY MRAOBSTA, OR IF THE
C     VCODE IS CLEARLY ILLEGAL, RETURN WITH ERROR.
C     ------------------------------------------------------------------
      IF(UAPT_INIT(CD).NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MGETRAOBC: SELECTED SUBSYSTEM NOT INITIALIZED')
         GO TO 900
      ELSE IF(ATIME.NE.LAST_UAPT_ATIME(CD).OR.ATIME.EQ.'         ')THEN
         STATUS = TIME_NOTINIT_P
         CALL MERROR('MGETRAOBC: TIME NOT INITIALIZED BY MUAPTSTA')
         GO TO 900
      ELSE
         CALL MGETVCN(VCODE,VCN,VCT,STATUS)
         IF(STATUS.NE.SUCCESS_P)THEN
            GO TO 900

C     ------------------------------------------------------------------
C     REGARDLESS OF WHAT MGETVCN FOUND, THE ONLY RAOB CHARACATER 
C     VARIABLE IS RELEASE TIME.
C     ------------------------------------------------------------------
         ELSE IF(VCN.NE.RAOBRT_VN_P)THEN
            STATUS = INV_VCN_P
            CALL MERROR('MGETRAOBC: INVALID VARIABLE CODE')
            GO TO 900
C     ------------------------------------------------------------------
C     NOT SO FAST.  IF THIS IS THE AWIPS DATABASE, THE RELEASE TIME
C     VARIABLE DOES EXIST, BUT IT'S FILLED IN WITH 0'S, WHICH ARE
C     MEANINGLESS...  
C     ------------------------------------------------------------------
         ELSE IF(CDBTYPE.EQ.AWIPS_DB_P)THEN
            STATUS = VAR_NOTINDB_P
            CALL MERROR('MGETRAOBC: VARIABLE NOT IN SELECTED DATABASE')
            GO TO 900
         ENDIF
      ENDIF

      NSTA = UAPT_LNUM(CD)
      IF(NSTA.EQ.0)THEN
         STATUS = NO_DATA_P
         GO TO 900
      ENDIF

      FNUM = 0

C     ------------------------------------------------------------------
C     NOTE THAT WE LOOP THROUGH UAPT_FNUM TO SEE WHICH FILES ARE NEEDED
C     AND NOT THROUGH UAPT_NFILES.  THIS IS DONE AS JUST BECAUSE A FILE
C     GOT READ DOESN'T MEAN ANY OF ITS RECORDS ACTUALLY WERE EXTRACTED
C     WHEN ALL THE FILTERING WAS DONE IN MUAPTSTA.  THEREFORE, WE'LL
C     ONLY PROCESS EACH FILE WITH RECORDS IN USE.
C     ------------------------------------------------------------------
      DO 100 I = 1, NSTA

C     ------------------------------------------------------------------
C     ALREADY HANDLED THIS FILE.
C     ------------------------------------------------------------------
         IF(FNUM.EQ.UAPT_FNUM(I,CD))GO TO 100

         IF(FNUM.EQ.0)THEN

C     ------------------------------------------------------------------
C     IF THIS IS THE FIRST TIME WE'VE BEEN HERE, FILL BLANKS INTO
C     THE CALLER'S ARRAY.  (NOTE THAT THERE ARE NO MISSING DATA FLAGS
C     FOR CHARACTER VARIABLES.)
C     ------------------------------------------------------------------
            DO 118 J = 1, NSTA

               CDATA(J) = '         '

 118        CONTINUE

         ENDIF

         FNUM = UAPT_FNUM(I,CD)

C     ------------------------------------------------------------------
C     READ THE VARIABLE.  IF THERE'S AN ERROR, THE SUBROUTINE WILL HAVE
C     SET STATUS & CALLED MERROR.  IF THERE ISN'T AN ERROR, INDICATE
C     THAT WE ACTUALLY READ SOMETHING.
C     ------------------------------------------------------------------
         CALL MRDDBL('relTime',UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),
     1               1,UAPT_NRECS(FNUM,CD),MISS_P,DTIME,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900

         HAVE_ANY = .TRUE.

C     ------------------------------------------------------------------
C     EXTRACT DESIRED RECORDS AND CONVERT INTO A STRING IN THE CALLER'S
C     ARRAY.
C     ------------------------------------------------------------------
         DO 120 J = I, NSTA

            IF(UAPT_FNUM(J,CD).NE.FNUM)GO TO 100

            IF(DTIME(UAPT_RNUM(J,CD)).NE.MISS_P)THEN

               RTIME = DTIME(UAPT_RNUM(J,CD))
               RTIME = RTIME - 1325376000
               CALL M_MKFNAM(RTIME,CDATA(J),K)
               IF(K.NE.SUCCESS_P)CDATA(J) = '         '

            ENDIF

            IF(J.EQ.NSTA)GO TO 900

 120     CONTINUE

 100  CONTINUE

 900  IF(STATUS.NE.SUCCESS_P)THEN

         NSTA = 0

      ELSE IF(.NOT.HAVE_ANY)THEN

         STATUS = NO_DATA_P
         NSTA = 0

      ENDIF

      RETURN
      END

C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
