C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MRDDIM      READ DIMENSIONS FOR A NETCDF VARIABLE
C   PRGMMR: M. BARTH         ORG: FSL        DATE:  00-03-24
C
C ABSTRACT: READ DIMENSIONS FOR A NETCDF VARIABLE ON AN OPEN FILE.
C
C PROGRAM HISTORY LOG:
C   00-03-24  M. BARTH    ORIGINAL VERSION
C   01-07-11  M. BARTH    - ADDED VAR_NOTINDB_P ERROR RETURN.
C                         - CHANGED HANDLING OF VNAME IN MERROR CALLS
C                           TO CONFORM WITH G77 COMPILER
C   05-06-06  L. BENJAMIN KNOCK OUT MISSING QC VARIABLES MERROR CALLS
C
C USAGE:    CALL MRDDIM (VNAME,NCID,NVDIMS,DIMNAM,DIMSIZ,STATUS)
C
C   INPUT ARGUMENT LIST:
C     VNAME    - C       NETCDF VARIABLE NAME
C     NCID     - I       ID OF THE OPEN NETCDF QC FILE
C
C   OUTPUT ARGUMENT LIST:
C     NVDIMS   - I       NUMBER OF DIMENSIONS
C     DIMNAM   - CA      DIMENSION NAMES
C     DIMSIZ   - IA      NUMBER OF ARRAY ELEMENTS FOR EACH DIMENSION
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     WHATEVER NETCDF FILE'S OPEN ON NCID.
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, M_LSTCHR
C     NETCDF:    NCVID, NCVINQ, NCDINQ
C
C REMARKS:
C   NONE
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MRDDIM(VNAME,NCID,NVDIMS,DIMNAM,DIMSIZ,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'NETCDFI'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*(*) VNAME,DIMNAM(*)
      INTEGER NCID,NVDIMS,DIMSIZ(*),STATUS

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      CHARACTER*(MAXNCNAM) VARNAM,ERRVAR
      INTEGER J,K,N,RCODE,VARTYP,NVATTS,VDIMS(MAXVDIMS),M_LSTCHR

      STATUS = NC_READ_P

C     ------------------------------------------------------------------
C     GET THE VARIABLE ID FROM ITS NAME.  INQUIRE ABOUT ITS DIMENSIONS.
C     ------------------------------------------------------------------
      J = LEN(VNAME)
      N = M_LSTCHR(VNAME,J)
      ERRVAR = VNAME(1:N)
      J = NCVID(NCID,VNAME,RCODE)
      IF(RCODE.NE.0)THEN
         IF(RCODE.EQ.NCENOTVR)THEN
            STATUS = VAR_NOTINDB_P
            IF(N.LT.4.OR.(VNAME(N-2:N).NE.'QCA'.AND.
     |           VNAME(N-2:N).NE.'QCR'))THEN
               CALL MERROR('MRDDIM: VARIABLE NOT IN SELECTED DATABASE')
            ENDIF
         ELSE
            CALL MERROR('MRDDIM: BAD NCVID - '//ERRVAR(1:N))
         ENDIF
         GO TO 900
      ENDIF
      CALL NCVINQ(NCID,J,VARNAM,VARTYP,NVDIMS,VDIMS,NVATTS,RCODE)
      IF(RCODE.NE.SUCCESS_P)THEN
         CALL MERROR('MRDDIM: BAD NCVINQ - '//ERRVAR(1:N))
         GO TO 900
      ENDIF
      DO 8551 K = 1, NVDIMS
         CALL NCDINQ(NCID,VDIMS(K),DIMNAM(K),DIMSIZ(K),RCODE)
         IF(RCODE.NE.SUCCESS_P)THEN
            CALL MERROR('MRDDIM: BAD NCDINQ - '//ERRVAR(1:N))
            GO TO 900
         ENDIF
 8551 CONTINUE

      STATUS = SUCCESS_P

 900  RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
