C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MHYDROSTA   GET HYDRO STATIONS FOR ONE TIME
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 01-07-24
C
C ABSTRACT: READ STATION INFO FOR HYDRO DATASETS FOR ONE TIME.
C
C PROGRAM HISTORY LOG:
C   01-07-24  M. BARTH    ORIGINAL VERSION
C   02-06-01  M. BARTH    RETURN "TOO MANY RECORDS" ERROR IF NUMBER
C                         OF FILES NEEDED FOR THE TIME WINDOW IS MORE
C                         THAN THE NUMBER THAT CAN BE USED -- THIS
C                         CHANGE ALLOWS US TO CHANGE THE AMOUNT OF
C                         TIME (AND THEREFORE VOLUME OF RECORDS)
C                         KEPT IN A SINGLE FILE BY ONLY CHANGING
C                         THE TEMPLATE -- ALLOWS ROOM FOR GROWTH.
C   03-10-03  M. BARTH    REPLACED NCOPN CALL WITH MMADISOPEN ROUTINE
C   04-08-19  M. BARTH    REPLACED NCCLOS CALL WITH MMADISCLS1 ROUTINE
C                         AND PUT THE YYYYMMDD_HHMM PART OF THE 
C                         FILENAMES INTO STRCCOM (WAS LOCAL)
C
C USAGE:    CALL MHYDROSTA (ATIME,NSTA,STANAM,WMOID,LAT,LON,ELEV,TIMEOB,
C                           PROVDR,STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     STANAM   - CA      STATION NAMES
C     WMOID    - IA      WMO ID NUMBERS
C     LAT      - RA      LATITUDES (N)
C     LON      - RA      LONGITUDES (E)
C     ELEV     - RA      STATION ELEVATIONS (M)
C     TIMEOB   - CA      YYJJJHHMM OBSERVATION TIMES
C     PROVDR   - CA      DATA PROVIDER NAMES
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS HYDRO NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, M_MKI4TM, MHYDROCLS, MSFILES, M_MKFNAM, 
C                M_MKWFNM, MHYDRORDSTA, MHYDROFLTR, MMADISOPEN,
C                MMADISCLS1
C     NETCDF:    NCINQ, NCDINQ
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT BEFORE CALLING THIS ROUTINE.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXHYDRO_P IN
C     madiscon.f.  IF AFTER TIME & DOMAIN FILTERING THERE ARE MORE
C     THAN MXHYDRO_P RECORDS THIS ROUTINE WILL RETURN WITH THE
C     "TOO MANY RECORDS" ERROR (TOO_MANY_REC_P).  THIS SHOULD ALERT
C     THE USER TO RESTRUCTURE HIS/HER CODE TO CHANGE HOW DATA
C     ARE BEING RETRIEVED:  E.G., USE A SMALLER TIME WINDOW AND
C     CALL THIS ROUTINE TWICE -- GET THE DESIRED RESULT BUT WITHOUT
C     EXCEEDING THE MAXIMUM NUMBER OF RECORDS LEGALLY HANDLED BY
C     THE MADIS CODE.
C   - THIS ROUTINE SHOULD BE CALLED WHENEVER ACCESS TO A NEW TIME
C     IS DESIRED.
C   - FOLLOWING THIS CALL, MGETHYDRO SHOULD BE CALLED TO READ
C     IN WHATEVER OBSERVATIONS ARE DESIRED FOR THIS TIME.  THE INFO
C     STORED IN THE STRCCOM COMMON BY THIS ROUTINE IS USED BY THE OTHER
C     ROUTINES TO FIGURE OUT WHICH RECORDS IT NEEDS ON NETCDF FILES
C     OPENED IN THIS ROUTINE.
C   - THE MADISCOM PROVIDER ARRAYS (NPVD, PVDNAME, ETC.) HAVE HYDRO
C     PROVIDERS IN ROW 1, HYDRO PROVIDERS IN ROW 2.
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MHYDROSTA (ATIME,NSTA,STANAM,WMOID,LAT,LON,ELEV,TIMEOB,
     1                      PROVDR,STATUS)


C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME,TIMEOB(*)
      CHARACTER*(*) STANAM(*),PROVDR(*)
      INTEGER NSTA,WMOID(*),STATUS
      REAL LAT(*),LON(*),ELEV(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,L,I4TIME,NFILES,START_TIME,RCODE
      INTEGER NDIMS,NVARS,NGATTS
      LOGICAL KEEP_GOING
      CHARACTER*9 FTIME
      CHARACTER*31 DUMMY

      INTEGER OBTIME(MXHYDRO_P*4),FNUML(MXHYDRO_P*4),RNUML(MXHYDRO_P*4)
      CHARACTER*10 STANAML(MXHYDRO_P*4)
      CHARACTER*(LDPNAM_P) PROVDRL(MXHYDRO_P*4)
      INTEGER NSTANEW,WMOIDL(MXHYDRO_P*4),SUBSRC(MXHYDRO_P*4)
      REAL LATL(MXHYDRO_P*4),LONL(MXHYDRO_P*4),ELEVL(MXHYDRO_P*4)

C     ------------------------------------------------------------------
C     IF THE HYDRO SUBSYSTEM HASN'T BEEN INITIALIZED, RETURN WITH ERROR.
C     OTHERWISE, CLOSE ANY OPEN NETCDF FILES AND INITIALIZE OTHER DATA
C     STRUCTURES.
C     ------------------------------------------------------------------
      IF(HYDRO_INIT.NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MHYDROSTA: SELECTED SUBSYSTEM NOT INITIALIZED -'//
     1               ' HYDRO')
         RETURN
      ENDIF

      CALL M_MKI4TM(ATIME,I4TIME,STATUS)
      IF(STATUS.NE.SUCCESS_P)THEN
         CALL MERROR('MHYDROSTA: INVALID TIME')
         RETURN
      ENDIF
      CALL MHYDROCLS
      LAST_HYDRO_ATIME = '         '
      HYDRO_NFILES = 0
      HYDRO_LNUM = 0
      KEEP_GOING = .TRUE.
      CDTYPE = HYD_DS_P
      CDBTYPE = HYDRO_DBTYPE

C     ------------------------------------------------------------------
C     LOOP THROUGH THE DATASETS.
C     ------------------------------------------------------------------
      DO 1 I = 1, MAX_HYDRODSET_P

C     ------------------------------------------------------------------
C     DETERMINE HOW MANY FILES NEED TO BE READ IN TO SATISFY THE TIME
C     WINDOW.
C     ------------------------------------------------------------------
         IF(HYDRODSET_ENBL(I))THEN

            CALL MSFILES(MAX_SFCDSET_P+MAX_UAPTDSET_P+I,I4TIME,
     1                   START_TIME,NFILES)
            IF(NFILES.GT.HYDRO_MXSTRF/MAX_HYDRODSET_P)THEN
               NSTA = 0
               LAST_HYDRO_ATIME = '         '
               STATUS = TOO_MANY_REC_P
               CALL MERROR('MHYDROSTA: TOO MANY RECORDS REQUESTED')
               RETURN
            ENDIF

            K = 1

C     ------------------------------------------------------------------
C     LOOP FOR ALL FILES IN THE DATASET:
C     - CREATE THE FILENAME.
C     - OPEN THE FILE AND GET THE NO. OF RECORDS, STORE NCID & NREC.
C       IN COMMON FOR SUBSEQUENT READS.
C     - READ IN THE STATION INFO INTO LOCAL ARRAYS.
C     ------------------------------------------------------------------
            DO 5 J = 1, NFILES

               HYDRO_NFILES = HYDRO_NFILES + 1
               CALL M_MKFNAM(START_TIME,FTIME,STATUS)
               START_TIME = START_TIME + HYDRODSET_INCR(I)

               CALL M_MKWFNM(FTIME,HYDRO_FNAME(HYDRO_NFILES),STATUS)

               CALL MMADISOPEN(HYDRODIR(I),HYDRODIRLEN(I),
     1                         HYDRO_FNAME(HYDRO_NFILES),
     2                         HYDRO_NCID(HYDRO_NFILES),RCODE)
               IF(RCODE.NE.0)THEN
                  HYDRO_NCID(HYDRO_NFILES) = -1
                  GO TO 10
               ENDIF

               CALL NCINQ(HYDRO_NCID(HYDRO_NFILES),NDIMS,NVARS,NGATTS,
     1                    HYDRO_RECDIM(HYDRO_NFILES),RCODE)
               IF(RCODE.NE.0)GO TO 10
               CALL NCDINQ(HYDRO_NCID(HYDRO_NFILES),
     1                     HYDRO_RECDIM(HYDRO_NFILES),DUMMY,
     2                     HYDRO_NRECS(HYDRO_NFILES),RCODE)
               IF(RCODE.NE.0.OR.HYDRO_NRECS(HYDRO_NFILES).EQ.0)GO TO 10

C     ------------------------------------------------------------------
C     IF WE'VE SOMEHOW EXCEEDED THE DIMENSION OF OUR ARRAYS, DON'T
C     TRY TO READ ANYMORE, BUT DO RETURN WITH WHAT WE'VE ALREADY GOT.
C     NOTE THAT WE DON'T DECLARE A FATAL ERROR, AS WE DO WHEN THE
C     POST-FILTERED AMOUNT IS GREATHER THAN MXHYDRO_P.  THIS IS BECAUSE
C     THIS ERROR WOULD BE A RESULT OF INTERNAL LOGIC PROBLEMS AND
C     THE USER WHO STUMBLES ACROSS IT SHOULDN'T BE EXPECTED TO REWRITE
C     HIS CODE TO COMPENSATE...
C     ------------------------------------------------------------------
               IF(K-1+HYDRO_NRECS(HYDRO_NFILES).GT.MXHYDRO_P*4)THEN
                  KEEP_GOING = .FALSE.
                  CALL MMADISCLS1(HYDRO_NCID(HYDRO_NFILES),HYDRODIR(I),
     1                            HYDRODIRLEN(I),
     2                            HYDRO_FNAME(HYDRO_NFILES))
                  HYDRO_NCID(HYDRO_NFILES) = -1
                  HYDRO_NFILES = HYDRO_NFILES - 1
                  GO TO 100
               ENDIF

               CALL MHYDRORDSTA(I+MAX_SFCDSET_P+MAX_UAPTDSET_P,
     1                          HYDRO_NCID(HYDRO_NFILES),
     2                          HYDRO_RECDIM(HYDRO_NFILES),1,
     3                          HYDRO_NRECS(HYDRO_NFILES),MXHYDRO_P*4,
     4                          OBTIME(K),STANAML(K),WMOIDL(K),
     5                          PROVDRL(K),LATL(K),LONL(K),ELEVL(K),
     6                          SUBSRC(K),STATUS)
               IF(STATUS.EQ.SUCCESS_P)THEN

C     ------------------------------------------------------------------
C     PUT THE FILE AND RECORD NUMBERS, AND THE SOURCE, INTO COMMON AND
C     UPDATE K FOR NEXT FILE IN THIS DATASET.
C     ------------------------------------------------------------------
                  DO 4 L = K, K + HYDRO_NRECS(HYDRO_NFILES) - 1
                     FNUML(L) = HYDRO_NFILES
                     RNUML(L) = L - K + 1
 4                CONTINUE
                  K = K + HYDRO_NRECS(HYDRO_NFILES)
                  HYDRO_SOURCE(HYDRO_NFILES) = I
                  GO TO 5
               ENDIF

C     ------------------------------------------------------------------
C     ERROR WITH THE NETCDF FILE.  CLOSE IT (IF OPEN) AND RELEASE ITS
C     SLOT IN THE COMMON.
C     ------------------------------------------------------------------
 10            IF(HYDRO_NCID(HYDRO_NFILES).GE.0)
     1            CALL MMADISCLS1(HYDRO_NCID(HYDRO_NFILES),HYDRODIR(I),
     2                            HYDRODIRLEN(I),
     3                            HYDRO_FNAME(HYDRO_NFILES))
               HYDRO_NCID(HYDRO_NFILES) = -1
               HYDRO_NFILES = HYDRO_NFILES - 1

 5          CONTINUE

C     ------------------------------------------------------------------
C     IF WE HAVE ANYTHING FOR THIS DATASET, FILTER RECS WE DON'T WANT:
C     - MISSING LAT, LON OR ELEV
C     - OUTSIDE THE TIME WINDOW
C     - MULTIPLES WITHIN THE TIME WINDOW (IF RECWIN SO INDICATES)
C     - PROVIDERS THAT HAVE BEEN DISABLED BY MSETPVDR
C     ------------------------------------------------------------------
 100        K = K - 1
            IF(K.EQ.0)THEN
               IF(KEEP_GOING)THEN
                  GO TO 1
               ELSE
                  GO TO 900
               ENDIF
            ENDIF

            CALL MHYDROFLTR(ATIME,MINBCK,MINFWD,RECWIN,I,MISS_P,
     1                      PROVDR_ENBL(1,2),K,OBTIME,STANAML,WMOIDL,
     2                      PROVDRL,SUBSRC,LATL,LONL,ELEVL,FNUML,RNUML,
     3                      NSTANEW)

C     ------------------------------------------------------------------
C     THE CALLER IS EXPECTED TO HAVE MXHYDRO_P RECORDS AVAILABLE.  IF
C     THIS WOULD PUT HIM OVER THE TOP, RETURN WITH AN ERROR (SEE
C     REMARKS SECTION ABOVE).
C     ------------------------------------------------------------------
            IF(NSTANEW+HYDRO_LNUM.GT.MXHYDRO_P)THEN
               NSTA = 0
               LAST_HYDRO_ATIME = '         '
               STATUS = TOO_MANY_REC_P
               CALL MERROR('MHYDROSTA: TOO MANY RECORDS REQUESTED')
               RETURN
            ENDIF

C     ------------------------------------------------------------------
C     TRANSFER REMAINING RECORDS TO CALLER'S ARRAYS, AND UPDATE INFO
C     IN COMMON.
C     ------------------------------------------------------------------
            DO 200 J = 1, NSTANEW
               K = HYDRO_LNUM + J
               STANAM(K) = STANAML(J)
               WMOID(K) = WMOIDL(J)
               LAT(K) = LATL(J)
               LON(K) = LONL(J)
               ELEV(K) = ELEVL(J)
               CALL M_MKFNAM(OBTIME(J),TIMEOB(K),STATUS)
               PROVDR(K) = PROVDRL(J)

               HYDRO_FNUM(K) = FNUML(J)
               HYDRO_RNUM(K) = RNUML(J)

 200        CONTINUE

            HYDRO_LNUM = HYDRO_LNUM + NSTANEW

         ENDIF

         IF(.NOT.KEEP_GOING)GO TO 900

 1    CONTINUE

C     ------------------------------------------------------------------
C     IF WE GOT ANYTHING AT ALL, TELL CALLER HOW MANY STATIONS AND
C     UPDATE THE ATIME KEPT IN COMMON SO SUBSEQUENT READS FOR THE
C     SAME TIME WILL USE THE FILE/RECORD INFO WE JUST WORKED SO HARD
C     TO CREATE...
C     ------------------------------------------------------------------
 900  IF(HYDRO_LNUM.GT.0)THEN
         NSTA = HYDRO_LNUM
         LAST_HYDRO_ATIME = ATIME
         STATUS = SUCCESS_P
      ELSE
         NSTA = 0
         LAST_HYDRO_ATIME = '         '
         STATUS = NO_DATA_P
         CALL MERROR('MHYDROSTA: NO DATA FOR '//ATIME)
      ENDIF

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
