C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MGETSNOWC    GET SNOW CHARACTER DATA FOR ONE VARIABLE
C   PRGMMR: L. BENJAMIN      ORG: FSL        DATE: 05-11-18
C
C ABSTRACT: READ SNOW CHARACTER DATA FOR ALL STATIONS FOR ONE VARIABLE
C   AND TIME.
C
C PROGRAM HISTORY LOG:
C   05-11-18  L. BENJAMIN ORIGINAL VERSION
C   08-06-26  L. BENJAMIN REMOVED UNUSED VARIABLE COOPTIME
C
C USAGE:    CALL MGETSNOWC (ATIME,VCODE,NSTA,CDATA,STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C     VCODE    - C       VARIABLE CODE NAMES
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     CDATA    - CA      ARRAY OF RETURNED CHARACTER DATA
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS SNOW NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, MGETVCN, MGTCHR, MRDDBL, M_MKFNAM
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT AND MSNOWSTA BEFORE CALLING THIS
C     ROUTINE.  MSNOWSTA SHOULD BE CALLED FIRST WHENEVER ACCESS TO
C     A NEW TIME IS DESIRED.  IT STORES INFO IN THE STRCCOM COMMON
C     THAT IS USED BY THIS ROUTINE TO FIGURE OUT WHICH RECORDS ARE
C     NEEDED ON NETCDF FILES OPENED BY MSNOWSTA.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXSNOW_P IN
C     madiscon.f, AND TO MATCH THE DIMENSIONS OF THE LARGEST VERSION
C     OF THE VARIABLE IN ANY DATASET.  SEE THE MADIS USER'S GUIDE
C     TO SEE WHAT DIMENSIONS SHOULD BE USED FOR THE CHARACTER
C     VARIABLES, OR SEE THE VALUES OF VCLEN FOR EACH CHARACTER
C     VARIABLE IN THE SNOWTBL.TXT FILE.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MGETSNOWC(ATIME,VCODE,NSTA,CDATA,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME
      CHARACTER*(*) VCODE
      INTEGER NSTA,STATUS
      CHARACTER*1 CDATA(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,FNUM,DSN,LEN1REC,VCN,NCLEN,RTIME
      LOGICAL HAVE_ANY,HAVE_DSN
      CHARACTER*1 CTMP(MAX_CHAR_VLEN_P*MXSNOW_P),VCT
      LOGICAL PROC_FILE(SNOW_MXSTRF),SUBPVDR
      CHARACTER*9 CTMP1
      INTEGER TOT,LAST_BEST_STATUS
      INTEGER CD

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(CTMP,TMP_L1_C1)

C     ------------------------------------------------------------------
C     IF THE SNOW SUBSYSTEM HASN'T BEEN INITIALIZED, OR IF THE REQUESTED
C     TIME DOESN'T MATCH THE TIME LAST PROCESSED BY MSNOWSTA, OR IF THE
C     VCODE IS CLEARLY ILLEGAL, RETURN WITH ERROR.
C     ------------------------------------------------------------------
      IF(SNOW_INIT.NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MGETSNOWC: SELECTED SUBSYSTEM NOT INITIALIZED - '
     1        //'SNOW')
         GO TO 900
      ELSE IF(ATIME.NE.LAST_SNOW_ATIME.OR.ATIME.EQ.'         ')THEN
         STATUS = TIME_NOTINIT_P
         CALL MERROR('MGETSNOWC: TIME NOT INITIALIZED BY MSNOWSTA')
         GO TO 900
      ELSE 
         CALL MGETVCN(VCODE,VCN,VCT,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900
      ENDIF

      CD = CDTYPE
C     ------------------------------------------------------------------
C     SET UP STRUCTURES TO ALLOW US TO POINT TO PROCESS EITHER A
C     REGULAR CHARACTER VARIABLE, DEFINED IN THE VARIABLE DATA 
C     STRUCTURES, OR TO PROCESS MAX/MIN TEMPERATURE TIMES, WHICH WILL
C     BE READ IN AS NUMBERS THEN CONVERTED TO CHARACTER STRINGS.
C     ------------------------------------------------------------------
      SUBPVDR = .FALSE.

      IF(VCN.EQ.SUBPVDR_VN_P)THEN

         SUBPVDR = .TRUE.
         NCLEN = 11

      ENDIF


      NSTA = SNOW_LNUM
      IF(NSTA.EQ.0)THEN
         STATUS = NO_DATA_P
         GO TO 900
      ENDIF

      FNUM = 0
      HAVE_ANY = .FALSE.
      HAVE_DSN = .FALSE.

      DO 2 I = 1, SNOW_MXSTRF
         PROC_FILE(I) = .FALSE.
 2    CONTINUE
      TOT = 0
C     ------------------------------------------------------------------
C     NOTE THAT WE LOOP THROUGH SNOW_FNUM TO SEE WHICH FILES ARE NEEDED
C     AND NOT THROUGH SNOW_NFILES.  THIS IS DONE AS JUST BECAUSE A FILE
C     GOT READ DOESN'T MEAN ANY OF ITS RECORDS ACTUALLY WERE EXTRACTED
C     WHEN ALL THE FILTERING WAS DONE IN MSNOWSTA.  THEREFORE, WE'LL
C     ONLY PROCESS EACH FILE WITH RECORDS IN USE.
C     ------------------------------------------------------------------

      DO 100 I = 1, NSTA

C     ------------------------------------------------------------------
C     ALREADY HANDLED THIS FILE.
C     ------------------------------------------------------------------
         IF(PROC_FILE(SNOW_FNUM(I)))GO TO 100

         FNUM = SNOW_FNUM(I)
         PROC_FILE(FNUM) = .TRUE.
         DSN = MAX_SFCDSET_P + MAX_UAPTDSET_P + MAX_HYDRODSET_P +
     1        MAX_SATWDSET_P + MAX_SATSDSET_P + MAX_SATRDSET_P + 
     2        SNOW_SOURCE(FNUM)

C     ------------------------------------------------------------------
C     THE VARIABLE'S NOT ASSOCIATED WITH THIS SOURCE DATASET.
C     ------------------------------------------------------------------
         IF(CD.NE.SNOW_DS_P)GO TO 100

         IF(VLEN(VCN,DSN).EQ.0.OR.(VCN.EQ.STALOC_VN_P.AND.
     1        CDBTYPE.EQ.AWIPS_DB_P.AND.CD.NE.SNOW_DS_P))GO TO 100

C     ------------------------------------------------------------------
C     THE VARIABLE'S NOT CHARACTER DATA TYPE:  THIS WILL BE
C     TRUE FOR ANY DATASET FOR WHICH THIS VARIABLE APPLIES, AND IS
C     AN ILLEGAL OPTION.
C     ------------------------------------------------------------------
         IF(VDTYPE(VCN,DSN).NE.'c')THEN
            STATUS = INV_DTYPE_P
            CALL MERROR('MGETSNOWC: INVALID VARIABLE DATA TYPE')
            GO TO 900
         ENDIF

         IF(.NOT.HAVE_DSN)THEN

C     ------------------------------------------------------------------
C     NOW THAT WE HAVE A VALID (VCN,DSN), WE NOW KNOW THE LENGTH OF
C     THE CHARACTER RECORDS TO BE RETURNED TO THE CALLER, AND CAN FILL
C     BLANKS INTO THE CALLER'S ARRAY.  (NOTE THAT THERE ARE NO MISSING
C     DATA FLAGS FOR CHARACTER VARIABLES.)
C     ------------------------------------------------------------------
            HAVE_DSN = .TRUE.
            IF(.NOT.SUBPVDR)NCLEN = VCLEN(VCN,DSN)

            DO 118 J = 1, NSTA

               DO 119 K = 1, NCLEN

                  CDATA((J-1)*NCLEN+K) = ' '

 119           CONTINUE

 118        CONTINUE

         ENDIF

C     ------------------------------------------------------------------
C     READ THE VARIABLE.  IF THERE'S AN ERROR, THE SUBROUTINE WILL HAVE
C     SET STATUS & CALLED MERROR.  IF THERE ISN'T AN ERROR, INDICATE
C     THAT WE ACTUALLY READ SOMETHING.
C     ------------------------------------------------------------------
         CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),SNOW_NCID(FNUM),
     1        SNOW_RECDIM(FNUM),1,SNOW_NRECS(FNUM),CTMP,
     2        LEN1REC,STATUS)
            

         IF(I.EQ.1)THEN
            LAST_BEST_STATUS = STATUS
         ENDIF
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            GO TO 100
         ELSE IF(STATUS.NE.SUCCESS_P)THEN
            GO TO 900
         ELSE
            LAST_BEST_STATUS = STATUS
         ENDIF

         HAVE_ANY = .TRUE.

C     ------------------------------------------------------------------
C     EXTRACT DESIRED RECORDS INTO CALLER'S ARRAY.  NOTE THAT THE
C     RETURNED SIZE (NCLEN) WILL BE .GE. THE ACTUAL SIZE (LEN1REC).
C     THIS ALLOWS SLIGHTLY DIFFERENT SIZES IN DIFFERENT DATASETS TO
C     BE TRANSPARENT TO THE CALLER.  ALSO, REPLACE NULLS WITH BLANKS
C     (FOR FORTRAN USERS).
C     ------------------------------------------------------------------
         IF(.NOT.
     1        (SUBPVDR.AND.CD.EQ.SNOW_DS_P))THEN

            DO 120 J = I, NSTA

               IF(SNOW_FNUM(J).NE.FNUM)GO TO 120

               DO 121 K = 1, LEN1REC

                  IF(ICHAR(CTMP((SNOW_RNUM(J)-1)*LEN1REC+K)).NE.0)THEN
                     CDATA((J-1)*NCLEN+K) =
     1                    CTMP((SNOW_RNUM(J)-1)*LEN1REC+K)
                  ELSE
                     CDATA((J-1)*NCLEN+K) = ' '
                  ENDIF

 121           CONTINUE
               TOT = TOT + 1

 120        CONTINUE

         ELSE IF(SUBPVDR.AND.CD.EQ.SNOW_DS_P)THEN

C     ------------------------------------------------------------------
C     THE SUBPROVIDER FIELD IS IN COLUMNS 40-50 OF THE stationName
C     VARIABLE.
C     ------------------------------------------------------------------
            DO 122 J = I, NSTA

               IF(SNOW_FNUM(J).NE.FNUM)GO TO 122

               DO K = 1, NCLEN

                  IF(ICHAR(CTMP((SNOW_RNUM(J)-1)*LEN1REC+K+39)).NE.0)
     1                 THEN
                     CDATA((J-1)*NCLEN+K) =
     1                    CTMP((SNOW_RNUM(J)-1)*LEN1REC+K+39)
                  ELSE
                     CDATA((J-1)*NCLEN+K) = ' '
                  ENDIF

               ENDDO
               TOT = TOT + 1

 122        CONTINUE

         ENDIF

 100  CONTINUE

      IF(TOT.EQ.0)THEN
         HAVE_ANY = .FALSE.
      ELSE
         STATUS = LAST_BEST_STATUS
      ENDIF

 900  IF(STATUS.NE.SUCCESS_P)THEN

         NSTA = 0

      ELSE IF(.NOT.HAVE_ANY)THEN

         STATUS = NO_DATA_P
         NSTA = 0

      ENDIF

      RETURN
      END

C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
