C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MSFCPCHG    GET 3H PRESSURE CHANGE OBS
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 99-09-20
C
C ABSTRACT: GET 3H PRESSURE CHANGE OBS FOR ALL STATIONS IN ONE NETCDF
C   FILE FOR ONE TIME.
C
C PROGRAM HISTORY LOG:
C   99-09-20  M. BARTH    ORIGINAL VERSION
C   00-03-22  M. BARTH    RENAMED MXST_P TO MXSFC_P
C   01-05-03  M. BARTH    CHANGED MRDNUM/MRDCHR TO MGTNUM/MGTCHR
C   04-10-16  L. BENJAMIN ADDED NO SUCH VARIABLE CHECK FOR QCA CHECKS
C
C USAGE:    CALL MSFCPCHG (VCN,DSN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)
C
C   INPUT ARGUMENT LIST:
C     VCN      - I       VARIABLE CODE NUMBER FOR 3H PRESSURE CHANGE
C     DSN      - I       DATASET CODE NUMBER
C     FNUM     - I       FILE NUMBER (INDEX IN COMMON) OF NETCDF FILE
C
C   OUTPUT ARGUMENT LIST:
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - RA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - RA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     NETCDF FILE OPENED USING DATA STRUCTURES FOR FNUM IN STRCCOM
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MGTNUM, MGTCHR
C
C REMARKS:
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - PCHG IS NORMALLY STORED AS AN ABSOLUTE VALUE, AND THE PRESSURE
C     CHANGE CHARACTER IS USED TO DETERMINE THE SIGN
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MSFCPCHG (VCN,DSN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER VCN,DSN,FNUM,STATUS
      REAL OB(*),QCAPP(*),QCRES(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      REAL PCHAR(MXSFC_P)
      INTEGER I,LEN1REC

C     ------------------------------------------------------------------
C     READ THE PCHG OBS & THE PCHG CHARACTER.  THEN USE THE CHARACTER
C     TO SET THE SIGN OF THE OBS, CONVERT SAO PCHG'S FROM HPA TO PA,
C     FILL IN THE QC, AND RETURN TO CALLER.
C     ------------------------------------------------------------------
      CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),SFC_NCID(FNUM),
     1            SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),MISS_P,OB,STATUS)
      IF(STATUS.NE.SUCCESS_P)RETURN

      CALL MGTNUM(VNAME(PCHCHR_VN_P,DSN)(1:VLEN(PCHCHR_VN_P,DSN)),
     1            SFC_NCID(FNUM),SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),
     3            MISS_P,PCHAR,STATUS)
      IF(STATUS.NE.SUCCESS_P)RETURN

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
      QCSTATUS = EQCOK_P

      IF(VQC(VCN,DSN).EQ.'Q')THEN

         CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCA',
     1               SFC_NCID(FNUM),SFC_RECDIM(FNUM),1,
     2               SFC_NRECS(FNUM),MISS_P,QCAPP,STATUS)
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            QCSTATUS = EQCFAILED_P
            STATUS = SUCCESS_P
            DO I = 1, SFC_NRECS(FNUM)
               QCAPP(I) = 0
               QCRES(I) = 0
               QCDESC(I) = 'Z'
            ENDDO
         ELSE IF(STATUS.NE.SUCCESS_P)THEN
            RETURN
         ELSE
            CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCR',
     1               SFC_NCID(FNUM),SFC_RECDIM(FNUM),1,
     2               SFC_NRECS(FNUM),MISS_P,QCRES,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN

            CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'DD',
     1               SFC_NCID(FNUM),SFC_RECDIM(FNUM),1,
     2               SFC_NRECS(FNUM),QCDESC,LEN1REC,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN
         ENDIF
      ELSE
         QCSTATUS = EQCFAILED_P

         DO 11 I = 1, SFC_NRECS(FNUM)
            QCAPP(I) = 0
            QCRES(I) = 0
            QCDESC(I) = 'Z'
 11      CONTINUE

      ENDIF

      IF(DSN.EQ.SAO_DS_P)THEN

         DO 12 I = 1, SFC_NRECS(FNUM)

            IF(OB(I).NE.MISS_P)OB(I) = OB(I) * 100.

 12      CONTINUE

      ENDIF

C     ------------------------------------------------------------------
C     THE RELATIONSHIP OF PRESSURE CHANGE CHARACTER TO SIGN OF
C     ACTUAL PRESSURE CHANGE IS FOUND IN FMH-1.
C     ------------------------------------------------------------------
      DO 13 I = 1, SFC_NRECS(FNUM)

         IF(PCHAR(I).NE.MISS_P.AND.PCHAR(I).GE.5.AND.OB(I).NE.MISS_P)
     1      OB(I) = -OB(I)

 13   CONTINUE

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
