C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MGETHYDROC   GET HYDRO CHARACTER DATA FOR ONE VARIABLE
C   PRGMMR: L. BENJAMIN      ORG: FSL        DATE: 07-05-15
C
C ABSTRACT: READ HYDRO CHARACTER DATA FOR ALL STATIONS FOR ONE VARIABLE
C   AND TIME.
C
C PROGRAM HISTORY LOG:
C   07-05-14  L. BENJAMIN ORIGINAL VERSION
C                         COPIED FROM M. BARTH'S MGETSFCC
C   08-06-26  L. BENJAMIN REMOVED UNUSED VARIABLES: COOPTIME, 
C                         URBANETTIME, COOPVAR, AND URBANETVAR
C
C USAGE:    CALL MGETHYDROC (ATIME,VCODE,NSTA,CDATA,STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C     VCODE    - C       VARIABLE CODE NAMES
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     CDATA    - CA      ARRAY OF RETURNED CHARACTER DATA
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, MGETVCN, MGTCHR, MRDDBL, M_MKFNAM
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT AND MHYDROSTA BEFORE CALLING THIS
C     ROUTINE.  MHYDROSTA SHOULD BE CALLED FIRST WHENEVER ACCESS TO
C     A NEW TIME IS DESIRED.  IT STORES INFO IN THE STRCCOM COMMON
C     THAT IS USED BY THIS ROUTINE TO FIGURE OUT WHICH RECORDS ARE
C     NEEDED ON NETCDF FILES OPENED BY MHYDROSTA.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXHYDRO_P IN
C     madiscon.f, AND TO MATCH THE DIMENSIONS OF THE LARGEST VERSION
C     OF THE VARIABLE IN ANY DATASET.  SEE THE MADIS USER'S GUIDE
C     TO SEE WHAT DIMENSIONS SHOULD BE USED FOR THE CHARACTER
C     VARIABLES, OR SEE THE VALUES OF VCLEN FOR EACH CHARACTER
C     VARIABLE IN THE HYDROTBL.TXT FILE.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MGETHYDROC(ATIME,VCODE,NSTA,CDATA,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME
      CHARACTER*(*) VCODE
      INTEGER NSTA,STATUS
      CHARACTER*1 CDATA(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,FNUM,DSN,LEN1REC,VCN,NCLEN,RTIME
      LOGICAL HAVE_ANY,HAVE_DSN
      CHARACTER*1 CTMP(MAX_CHAR_VLEN_P*MXHYDRO_P),VCT
      LOGICAL PROC_FILE(HYDRO_MXSTRF),SUBPVDR
      CHARACTER*9 CTMP1
      DOUBLE PRECISION DTMP(MXHYDRO_P)
      INTEGER TOT,LAST_BEST_STATUS

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(CTMP,TMP_L1_C1)
      EQUIVALENCE(DTMP,TMP_L1_N1)

C     ------------------------------------------------------------------
C     IF THE HYDRO SUBSYSTEM HASN'T BEEN INITIALIZED, OR IF THE 
C     REQUESTED TIME DOESN'T MATCH THE TIME LAST PROCESSED BY 
C     MHYDROSTA, OR IF THE VCODE IS CLEARLY ILLEGAL, RETURN WITH ERROR.
C     ------------------------------------------------------------------
      IF(HYDRO_INIT.NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MGETYDROC: SELECTED SUBSYSTEM NOT INITIALIZED - '
     1        //'SFC')
         GO TO 900
      ELSE IF(ATIME.NE.LAST_HYDRO_ATIME.OR.ATIME.EQ.'         ')THEN
         STATUS = TIME_NOTINIT_P
         CALL MERROR('MGETHYDROC: TIME NOT INITIALIZED BY MHYDROSTA')
         GO TO 900
      ELSE 
         CALL MGETVCN(VCODE,VCN,VCT,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900
      ENDIF

C     ------------------------------------------------------------------
C     INIT 
C     ------------------------------------------------------------------

      NSTA = HYDRO_LNUM
      IF(NSTA.EQ.0)THEN
         STATUS = NO_DATA_P
         GO TO 900
      ENDIF

      FNUM = 0
      HAVE_ANY = .FALSE.
      HAVE_DSN = .FALSE.

      DO 2 I = 1, HYDRO_MXSTRF
         PROC_FILE(I) = .FALSE.
 2    CONTINUE
      TOT = 0
C     ------------------------------------------------------------------
C     NOTE THAT WE LOOP THROUGH HYDRO_FNUM TO SEE WHICH FILES ARE NEEDED
C     AND NOT THROUGH HYDRO_NFILES.  THIS IS DONE AS JUST BECAUSE A FILE
C     GOT READ DOESN'T MEAN ANY OF ITS RECORDS ACTUALLY WERE EXTRACTED
C     WHEN ALL THE FILTERING WAS DONE IN MHYDROSTA.  THEREFORE, WE'LL
C     ONLY PROCESS EACH FILE WITH RECORDS IN USE.
C     ------------------------------------------------------------------
      DO 100 I = 1, NSTA

C     ------------------------------------------------------------------
C     ALREADY HANDLED THIS FILE.
C     ------------------------------------------------------------------
         IF(PROC_FILE(HYDRO_FNUM(I)))GO TO 100

         FNUM = HYDRO_FNUM(I)
         PROC_FILE(FNUM) = .TRUE.
         DSN = MAX_SFCDSET_P + MAX_UAPTDSET_P + HYDRO_SOURCE(FNUM)


C     ------------------------------------------------------------------
C     THE VARIABLE'S NOT CHARACTER DATA TYPE:  THIS WILL BE
C     TRUE FOR ANY DATASET FOR WHICH THIS VARIABLE APPLIES, AND IS
C     AN ILLEGAL OPTION.
C     ------------------------------------------------------------------
         IF(VDTYPE(VCN,DSN).NE.'c')THEN
            STATUS = INV_DTYPE_P
            CALL MERROR('MGETHYDROC: INVALID VARIABLE DATA TYPE')
            GO TO 900
         ENDIF

         IF(.NOT.HAVE_DSN)THEN

C     ------------------------------------------------------------------
C     NOW THAT WE HAVE A VALID (VCN,DSN), WE NOW KNOW THE LENGTH OF
C     THE CHARACTER RECORDS TO BE RETURNED TO THE CALLER, AND CAN FILL
C     BLANKS INTO THE CALLER'S ARRAY.  (NOTE THAT THERE ARE NO MISSING
C     DATA FLAGS FOR CHARACTER VARIABLES.)
C     ------------------------------------------------------------------
            HAVE_DSN = .TRUE.
            NCLEN = VCLEN(VCN,DSN)

            DO 118 J = 1, NSTA

               DO 119 K = 1, NCLEN

                  CDATA((J-1)*NCLEN+K) = ' '

 119           CONTINUE

 118        CONTINUE

         ENDIF

C     ------------------------------------------------------------------
C     READ THE VARIABLE.  IF THERE'S AN ERROR, THE SUBROUTINE WILL HAVE
C     SET STATUS & CALLED MERROR.  IF THERE ISN'T AN ERROR, INDICATE
C     THAT WE ACTUALLY READ SOMETHING.
C     ------------------------------------------------------------------
         CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),HYDRO_NCID(FNUM)
     1        ,HYDRO_RECDIM(FNUM),1,HYDRO_NRECS(FNUM),CTMP,
     2        LEN1REC,STATUS)
            
         IF(I.EQ.1)THEN
            LAST_BEST_STATUS = STATUS
         ENDIF
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            GO TO 100
         ELSE IF(STATUS.NE.SUCCESS_P)THEN
            GO TO 900
         ELSE
            LAST_BEST_STATUS = STATUS
         ENDIF

         HAVE_ANY = .TRUE.

C     ------------------------------------------------------------------
C     EXTRACT DESIRED RECORDS INTO CALLER'S ARRAY.  NOTE THAT THE
C     RETURNED SIZE (NCLEN) WILL BE .GE. THE ACTUAL SIZE (LEN1REC).
C     THIS ALLOWS SLIGHTLY DIFFERENT SIZES IN DIFFERENT DATASETS TO
C     BE TRANSPARENT TO THE CALLER.  ALSO, REPLACE NULLS WITH BLANKS
C     (FOR FORTRAN USERS).
C     ------------------------------------------------------------------
         DO 120 J = I, NSTA

            IF(HYDRO_FNUM(J).NE.FNUM)GO TO 120

            DO 121 K = 1, LEN1REC

               IF(ICHAR(CTMP((HYDRO_RNUM(J)-1)*LEN1REC+K)).NE.0)THEN
                  CDATA((J-1)*NCLEN+K) =
     1                 CTMP((HYDRO_RNUM(J)-1)*LEN1REC+K)
               ELSE
                  CDATA((J-1)*NCLEN+K) = ' '
               ENDIF
               
 121        CONTINUE
            TOT = TOT + 1
            
 120     CONTINUE

 100  CONTINUE

      IF(TOT.EQ.0)THEN
         HAVE_ANY = .FALSE.
      ELSE
         STATUS = LAST_BEST_STATUS
      ENDIF

 900  IF(STATUS.NE.SUCCESS_P)THEN

         NSTA = 0

      ELSE IF(.NOT.HAVE_ANY)THEN

         STATUS = NO_DATA_P
         NSTA = 0

      ENDIF

      RETURN
      END

C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
