C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MSFCRDLFT   GET SFC ROAD LIQUID FREEZE TEMP OBS
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 01-07-30
C
C ABSTRACT: GET THE SFC ROAD LIQUID FREEZE TEMPERATURE OBS
C
C PROGRAM HISTORY LOG:
C   01-07-30  M. BARTH    ORIGINAL VERSION
C   04-10-16  L. BENJAMIN ADDED NO SUCH VARIABLE CHECK FOR QCA CHECKS
C
C USAGE:    CALL MSFCRDLFT (VCN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)
C
C   INPUT ARGUMENT LIST:
C     VCN      - I       VARIABLE CODE NUMBER
C     FNUM     - I       FILE NUMBER (INDEX IN COMMON) OF NETCDF FILE
C
C   OUTPUT ARGUMENT LIST:
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - RA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - RA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     NETCDF FILE OPENED USING DATA STRUCTURES FOR FNUM IN STRCCOM
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MGTNUM, MGTCHR
C
C REMARKS:
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - THIS ROUTINE IS NEEDED BECAUSE THE ROAD LIQUID FREEZE TEMP
C     VARIABLE USED TO HAVE A DIFFERENT NAME IN THE NETCDF FILE
C     THAN IT DOES NOW...
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MSFCRDLFT (VCN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER VCN,FNUM,STATUS
      REAL OB(*),QCAPP(*),QCRES(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,LEN1REC,DSN,LEN1,LEN2,NMLEN
      LOGICAL SAVE_VERBOSE,PASS1
      CHARACTER*20 NAME1
      CHARACTER*21 NAME2
      CHARACTER*22 VRNAM
      CHARACTER*1  N

C     ------------------------------------------------------------------
C     DATA STATEMENTS (KEEP AT BOTTOM OF DECLARATIONS)
C     ------------------------------------------------------------------
      DATA NAME1/'roadLiquidFreezeTemp'/
      DATA NAME2/'roadAntiIceFreezeTemp'/
      DATA LEN1/20/
      DATA LEN2/21/

C     ------------------------------------------------------------------
C     HERE'S THE DEAL.  THE RDLFT VARIABLES USED TO HAVE DIFFERENT NAMES
C     IN THE NETCDF FILES THAN THEY DO NOW.  WE'LL TURN OFF VERBOSE
C     ERROR HANDLING, THEN TRY TO READ THE VARIABLE WITH ITS CURRENT
C     NAME.  IF WE GET A VAR_NOTINDB_P ERROR, WE'LL TRY TO READ IT WITH
C     THE OLD NAME.  IF WE GET ANY OTHER ERROR ON THE FIRST ATTEMPT,
C     OR WE GET ANY ERROR ON THE SECOND ATTEMPT, THAT'S ALL SHE WROTE...
C     ------------------------------------------------------------------
      DSN = MESONET_DS_P
      SAVE_VERBOSE = VERBOSE
      VERBOSE = .FALSE.
      IF(VCN.EQ.RDLFT1_VN_P)THEN
         N = '1'
      ELSE IF(VCN.EQ.RDLFT2_VN_P)THEN
         N = '2'
      ELSE IF(VCN.EQ.RDLFT3_VN_P)THEN
         N = '3'
      ELSE IF(VCN.EQ.RDLFT4_VN_P)THEN
         N = '4'
      ENDIF
      VRNAM = NAME1(1:LEN1)//N
      NMLEN = LEN1 + 1
      PASS1 = .TRUE.

 100  CALL MGTNUM(VRNAM(1:NMLEN),SFC_NCID(FNUM),SFC_RECDIM(FNUM),1,
     1            SFC_NRECS(FNUM),MISS_P,OB,STATUS)
      IF(.NOT.(STATUS.EQ.VAR_NOTINDB_P.AND.PASS1))THEN

         VERBOSE = SAVE_VERBOSE
         IF(STATUS.NE.SUCCESS_P)THEN
            IF(VERBOSE)CALL MGTNUM(VRNAM(1:NMLEN),SFC_NCID(FNUM),
     1                             SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),
     2                             MISS_P,OB,STATUS)
            RETURN
         ENDIF

      ELSE 

         PASS1 = .FALSE.
         VRNAM = NAME2(1:LEN2)//N
         NMLEN = LEN2 + 1
         GO TO 100

      ENDIF

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
      QCSTATUS = EQCOK_P

      IF(VQC(VCN,DSN).EQ.'Q')THEN

         CALL MGTNUM(VRNAM(1:NMLEN)//'QCA',SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),MISS_P,QCAPP,
     2               STATUS)
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            QCSTATUS = EQCFAILED_P
            STATUS = SUCCESS_P
            DO 11 I = 1, SFC_NRECS(FNUM)
               QCAPP(I) = 0
               QCRES(I) = 0
               QCDESC(I) = 'Z'
 11         CONTINUE
         ELSE IF(STATUS.NE.SUCCESS_P)THEN
            RETURN
         ELSE
            CALL MGTNUM(VRNAM(1:NMLEN)//'QCR',SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),MISS_P,QCRES,
     2               STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN

            CALL MGTCHR(VRNAM(1:NMLEN)//'DD',SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),QCDESC,LEN1REC,
     2               STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN
         ENDIF
      ELSE
         QCSTATUS = EQCFAILED_P

         DO 1 I = 1, SFC_NRECS(FNUM)
            QCAPP(I) = 0
            QCRES(I) = 0
            QCDESC(I) = 'Z'
 1       CONTINUE

      ENDIF

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
