C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MMAPMDDBL   GET MAP DOUBLE VARIABLE DIMEN BY MODE
C   PRGMMR: L. BENJAMIN      ORG: FSL        DATE: 06-09-08
C
C ABSTRACT: GET MAP DOUBLE PRECISION VARIABLE THAT'S DIMENSIONED 
C   ONLY BY RECNUM AND MODE FROM ONE FILE FOR ONE TIME.
C
C PROGRAM HISTORY LOG:
C   06-09-08  L. BENJAMIN ORIGINAL VERSION
C
C USAGE:    CALL MMAPMDDBL (VCN,DSN,FNUM,OB,QCDESC,QCAPP,QCRES,
C                           STATUS)
C
C   INPUT ARGUMENT LIST:
C     VCN      - I       VARIABLE CODE NUMBER
C     DSN      - I       DATASET CODE NUMBER
C     FNUM     - I       FILE NUMBER (INDEX IN COMMON) OF NETCDF FILE
C
C   OUTPUT ARGUMENT LIST:
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - RA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - RA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     NETCDF FILE OPENED USING DATA STRUCTURES FOR FNUM IN STRCCOM
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MGTCHR, MGTNUM
C
C REMARKS:
C   - WIND MODE PARAMETERS ARE THE ONLY MAP VARIABLES WITH A "MODE"
C     DIMENSION, BUT NO BEAM DIMENSION, THUS THIS SPECIAL-HANDLING 
C     ROUTINE.  ONLY ONE MODE IS RETRIEVED AT A TIME.
C   - AT THE INITIAL WRITING, QC INFORMATION DOESN'T EXIST FOR
C     THESE VARIABLES, BUT IS HANDLED HERE IN THE CODE AS IF IT
C     WERE TO SIMPLIFY ADDING THIS FEATURE (IF DESIRED) LATER.
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MMAPMDDBL (VCN,DSN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER VCN,DSN,FNUM,STATUS
      DOUBLE PRECISION OB(*)
      REAL QCAPP(*),QCRES(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,L,LEN1REC,CD

      DOUBLE PRECISION OBTMP(3,MXMAP_P)
      REAL QCATMP(3,MXMAP_P),QCRTMP(3,MXMAP_P)
      CHARACTER*1 QCDTMP(3,MXMAP_P)

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(OBTMP,TMP_L2_N1)
      EQUIVALENCE(QCATMP,TMP_L2_N2)
      EQUIVALENCE(QCRTMP,TMP_L2_N3)
      EQUIVALENCE(QCDTMP,TMP_L2_C1)

C     ------------------------------------------------------------------
C     READ IN THE VARIABLE & ANY ASSOCIATED QC INFO INTO LOCAL ARRAYS.
C     ------------------------------------------------------------------
      CD = DSN - MAX_SFCDSET_P

      CALL MRDDBL(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),UAPT_NCID(FNUM,CD),
     1            UAPT_RECDIM(FNUM,CD),1,UAPT_NRECS(FNUM,CD),MISS_P,
     2            OBTMP,STATUS)
      IF(STATUS.NE.SUCCESS_P)RETURN

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
      QCSTATUS = EQCOK_P

      IF(VQC(VCN,DSN).EQ.'Q')THEN

         CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCA',
     1               UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     2               UAPT_NRECS(FNUM,CD),MISS_P,QCATMP,STATUS)
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            QCSTATUS = EQCFAILED_P
            STATUS = SUCCESS_P
            DO I = 1, UAPT_NRECS(FNUM,CD)
               DO J = 1, 3
                  QCATMP(J,I) = 0
                  QCRTMP(J,I) = 0
                  QCDTMP(J,I) = 'Z'
               ENDDO
            ENDDO
         ELSE IF(STATUS.NE.SUCCESS_P)THEN
            RETURN
         ELSE
            CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCR',
     1               UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     2               UAPT_NRECS(FNUM,CD),MISS_P,QCRTMP,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN

            CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'DD',
     1               UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     2               UAPT_NRECS(FNUM,CD),QCDTMP,LEN1REC,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN
         ENDIF
      ELSE
         QCSTATUS = EQCFAILED_P

         DO 3 I = 1, UAPT_NRECS(FNUM,CD)
            DO 4 J = 1, 3
               QCATMP(J,I) = 0
               QCRTMP(J,I) = 0
               QCDTMP(J,I) = 'Z'
 4          CONTINUE
 3       CONTINUE

      ENDIF

C     ------------------------------------------------------------------
C     DETERMINE WHICH MODE NUMBER THE CALLER WANTS, THEN RETURN THE DATA 
C     IN HIS ARRAYS AND RETURN.
C     ------------------------------------------------------------------
      IF(VCN.EQ.MAPCST_1_VN_P)THEN
         J = 1
      ELSE IF(VCN.EQ.MAPCST_2_VN_P)THEN
         J = 2
      ELSE IF(VCN.EQ.MAPCST_3_VN_P)THEN
         J = 3
      ENDIF

      L = 1

      DO 12 I = 1, UAPT_NRECS(FNUM,CD)

         OB(L) = OBTMP(J,I)
         QCAPP(L) = QCATMP(J,I)
         QCRES(L) = QCRTMP(J,I)
         QCDESC(L) = QCDTMP(J,I)
         L = L + 1

 12   CONTINUE

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
