C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MUAPTHTP    GET UAPT LEVEL HEIGHTS (M MSL) OR P (PA)
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 03-07-02
C
C ABSTRACT: GET UPPER-AIR DATASET LEVEL HEIGHTS OR CALCULATE P FOR 
C   DESIRED PROFILE TYPE.
C
C PROGRAM HISTORY LOG:
C   02-05-01  M. BARTH    ORIGINAL VERSION (AS MMAPHT.F)
C   03-07-02  M. BARTH    RENAMED FROM MMAPHT TO MUAPTHTP, FOR USE
C                         BY MULTIPLE DATASETS.  SEE REMARKS SECTION.
C                         ALSO ADDED FULLQC ARGUMENT.
C   08-08-15  L. BENJAMIN ADDED MISS_P AS MISSING DATA ARGUMENT FOR
C                         M_ZTOPSA.
C
C USAGE:    CALL MUAPTHTP (VCN,DSN,FNUM,FULLQC,NV,OB,QCDESC,QCAPP,QCRES,
C                          STATUS)
C
C   INPUT ARGUMENT LIST:
C     VCN      - I       VARIABLE CODE NUMBER
C     DSN      - I       DATASET CODE NUMBER
C     FNUM     - I       FILE NUMBER (INDEX IN COMMON) OF NETCDF FILE
C     FULLQC   - L       .TRUE.  -- GET ALL 3 QC VARIABLES
C                        .FALSE. -- ONLY GET QCDESC
C     NV       - I       NUMBER OF LEVELS
C
C   OUTPUT ARGUMENT LIST:
C     OB       - RA      HEIGHTS (M MSL) OR PRESSURES (PA) FOR ALL
C                        STATIONS/LEVELS
C     QCDESC   - CA      QC DATA DESCRIPTORS -- SET TO NO QC
C     QCAPP    - RA      QC APPLIED WORD     -- SET TO NO QC
C     QCRES    - RA      QC RESULTS WORD     -- SET TO NO QC
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     NETCDF FILE OPENED USING DATA STRUCTURES FOR FNUM IN STRCCOM
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MGTNUM, M_ZTOPSA
C
C REMARKS:
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - THIS CAN BE USED FOR ANY UPPER-AIR DATASET WITH LEVELS THAT
C     HAS THE HEIGHTS AND STATION ELEVATIONS STORED IN NETCDF AS
C     'levels' AND 'elevation', AND THAT NEEDS PRESSURE CALCULATED
C     FROM THOSE HEIGHTS.
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MUAPTHTP (VCN,DSN,FNUM,FULLQC,NV,OB,QCDESC,QCAPP,QCRES,
     1                     STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER VCN,DSN,FNUM,NV,STATUS
      LOGICAL FULLQC
      REAL OB(NV,*)
      INTEGER QCAPP(NV,*),QCRES(NV,*)
      CHARACTER*1 QCDESC(NV,*)

C     ------------------------------------------------------------------
C     LOCAL
C     - DIMENSION ELEV TO THE LARGEST NUMBER OF MAX STATIONS FOR THE
C       DATASETS THAT THIS ROUTINE COVERS
C     ------------------------------------------------------------------
      INTEGER I,J,CD
      REAL ELEV(MXMAP_P)
      REAL M_ZTOPSA

C     ------------------------------------------------------------------
C     READ IN THE STATION ELEVATIONS AND THE LEVELS (HEIGHT ABOVE 
C     STATION).
C     ------------------------------------------------------------------
      CD = DSN - MAX_SFCDSET_P

      CALL MGTNUM('elevation',UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),
     1            1,UAPT_NRECS(FNUM,CD),MISS_P,ELEV,STATUS)
      IF(STATUS.NE.SUCCESS_P)RETURN

      CALL MGTNUM('levels',UAPT_NCID(FNUM,CD),UAPT_RECDIM(FNUM,CD),1,
     1            UAPT_NRECS(FNUM,CD),MISS_P,OB,STATUS)
      IF(STATUS.NE.SUCCESS_P)RETURN
      
C     ------------------------------------------------------------------
C     FILL MISSING FLAGS INTO THE QC, ADD THE STATION ELEVATIONS TO THE
C     LEVELS.
C     ------------------------------------------------------------------
      DO J = 1, UAPT_NRECS(FNUM,CD)

         DO I = 1, NV

            QCDESC(I,J) = 'Z'
            IF(OB(I,J).NE.MISS_P)OB(I,J) = OB(I,J) + ELEV(J)

         ENDDO

         IF(FULLQC)THEN

            DO I = 1, NV

               QCAPP(I,J) = 0
               QCRES(I,J) = 0

            ENDDO

         ENDIF
          
      ENDDO

C     ------------------------------------------------------------------
C     IF WE'RE HERE TO GET PRESSURE, USE THE U.S. STANDARD ATMOSPHERE
C     CALCULATION, AND CONVERT FROM MB TO PASCALS.
C     ------------------------------------------------------------------
      IF((CD.EQ.MAP_DS_P.AND.VCN.EQ.MAPP_VN_P).OR.
     1   (CD.EQ.RDMTR_DS_P.AND.VCN.EQ.RDMTRP_VN_P))THEN

         DO J = 1, UAPT_NRECS(FNUM,CD)

            DO I = 1, NV

               IF(OB(I,J).NE.MISS_P)OB(I,J) = M_ZTOPSA(OB(I,J),MISS_P)
     1              * 100.

            ENDDO

         ENDDO

      ENDIF

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
