C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MRDCHR      READ A CHARACTER NETCDF VARIABLE
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 99-09-16
C
C ABSTRACT: READ A CHARACTER NETCDF VARIABLE ON AN OPEN NETCDF FILE.
C
C PROGRAM HISTORY LOG:
C   99-09-16  M. BARTH    ORIGINAL VERSION
C   01-07-06  M. BARTH    - ADDED VAR_NOTINDB_P ERROR RETURN.
C                         - CHANGED HANDLING OF VNAME IN MERROR CALLS
C                           TO CONFORM WITH G77 COMPILER
C   02-06-03  M. BARTH    CHANGES TO ALLOW READING OF VARIABLES THAT
C                         DON'T HAVE THE RECDIM DIMENSION
C   05-04-18  L. BENJAMIN REMOVED WRITING ERROR MESSAGE FOR
C                         QCR AND QCA "VAR_NOTINDB_P" CASES.
C   08-06-13  L. BENJAMIN CHANGED "MADISCON" INCLUDE TO 
C                         "INTQC1CON2".  REMOVED STRCCOM INCLUDE.
C
C USAGE:    CALL MRDCHR (VNAME,NCID,RECDIM,STARTR,NRECS,VDATA,LEN1REC,
C                        STATUS)
C
C   INPUT ARGUMENT LIST:
C     VNAME    - C       NETCDF VARIABLE NAME
C     NCID     - I       ID OF THE OPEN NETCDF QC FILE
C     RECDIM   - I       DIMENSION ID OF THE FILE'S RECORD DIMENSION
C     STARTR   - I       STARTING RECORD TO READ
C     NRECS    - I       NUMBER OF RECORDS TO READ
C
C   OUTPUT ARGUMENT LIST:
C     VDATA    - CA      CHARACTER ARRAY WITH DATA FILLED IN
C     LEN1REC  - I       FOR VARIABLES WITH THE RECORD DIMENSION, THIS
C                        IS THE NUMBER OF CHARACTERS IN A SINGLE RECORD
C                        FOR OTHER VARIABLES, IT'S THE WHOLE NUMBER OF
C                        CHARACTERS READ IN
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     WHATEVER NETCDF FILE'S OPEN ON NCID.
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, M_LSTCHR
C     NETCDF:    NCVID, NCVINQ, NCDINQ, NCVGTC
C
C REMARKS:
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - THIS ROUTINE HAS ONLY BEEN TESTED FOR SINGLE-DIMENSIONED
C     (RECORD DIMENSION) CHARACTER*1 VARIABLES.  ON THE FACE OF
C     IT, THIS SHOULD WORK FOR ANY CHARACTER VARIABLE, BUT, I'VE
C     RUN INTO ODD THINGS WITH NETCDF CHARACTER VARIABLES IN THE
C     PAST, SO CAVEAT EMPTOR...
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MRDCHR(VNAME,NCID,RECDIM,STARTR,NRECS,VDATA,LEN1REC,
     1                  STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'INTQC1CON2'
      INCLUDE 'NETCDFI'


C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*(*) VNAME
      INTEGER NCID,RECDIM,STARTR,NRECS,LEN1REC,STATUS
      CHARACTER*(*) VDATA(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      CHARACTER*(MAXNCNAM) VARNAM,DIMNAM,ERRVAR
      INTEGER J,K,N,RCODE,VARTYP,NVDIMS,VDIMS(MAXVDIMS),NVATTS,LENSTR
      INTEGER DIMSIZ,START(MAXVDIMS),COUNT(MAXVDIMS),M_LSTCHR
      LOGICAL HAS_RECDIM

      STATUS = NC_READ_P

C     ------------------------------------------------------------------
C     GET THE VARIABLE ID FROM ITS NAME.  INQUIRE ABOUT ITS TYPE AND
C     DIMENSIONS.  FILL IN THE DIMENSIONS OF THE HYPERSLAB TO BE READ.
C     READ IT.  IF SUCCESSFUL, FILL IN THE CALLER'S ARRAY.
C
C     NOTE THAT DIV = 
C     ------------------------------------------------------------------
      J = LEN(VNAME)
      N = M_LSTCHR(VNAME,J)
      ERRVAR = VNAME(1:N)
      J = NCVID(NCID,VNAME,RCODE)
      IF(RCODE.NE.0)THEN
         IF(RCODE.EQ.NCENOTVR)THEN
            STATUS = VAR_NOTINDB_P
            IF(N.LT.4.OR.(VNAME(N-2:N).NE.'QCA'.AND.
     |           VNAME(N-2:N).NE.'QCR'))THEN
               CALL MERROR('MRDCHR: VARIABLE NOT IN SELECTED DATABASE')
            ENDIF
         ELSE
            CALL MERROR('MRDCHR: BAD NCVID - '//ERRVAR(1:N))
         ENDIF
         GO TO 900
      ENDIF
      CALL NCVINQ(NCID,J,VARNAM,VARTYP,NVDIMS,VDIMS,NVATTS,RCODE)
      IF(RCODE.NE.SUCCESS_P)THEN
         CALL MERROR('MRDCHR: BAD NCVINQ - '//ERRVAR(1:N))
         GO TO 900
      ENDIF
      LENSTR = 1
      HAS_RECDIM = .FALSE.
      DO 8551 K = 1, NVDIMS
         CALL NCDINQ(NCID,VDIMS(K),DIMNAM,DIMSIZ,RCODE)
         IF(RCODE.NE.SUCCESS_P)THEN
            CALL MERROR('MRDCHR: BAD NCDINQ - '//ERRVAR(1:N))
            GO TO 900
         ENDIF
         IF(K.LT.NVDIMS.OR.(NVDIMS.EQ.K.AND.VDIMS(K).NE.RECDIM))THEN
            START(K) = 1
            COUNT(K) = DIMSIZ
            LENSTR = LENSTR * DIMSIZ
         ELSE
            START(K) = STARTR
            COUNT(K) = NRECS
            LENSTR = LENSTR * NRECS
            HAS_RECDIM = .TRUE.
         ENDIF
 8551 CONTINUE

      CALL NCVGTC(NCID,J,START,COUNT,VDATA,LENSTR,RCODE)
      IF(RCODE.NE.SUCCESS_P)THEN
         CALL MERROR('MRDCHR: BAD NCVGTC - '//ERRVAR(1:N))
         GO TO 900
      ENDIF

      IF(HAS_RECDIM)LEN1REC = LENSTR/NRECS
      STATUS = SUCCESS_P

 900  RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
