C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MWISDOSTA     GET WISDOM STATIONS FOR ONE TIME
C   PRGMMR: L. BENJAMIN      ORG: FSL        DATE: 08-07-20
C
C ABSTRACT: READ STATION INFO FOR WISDOM DATASETS FOR ONE TIME.
C
C PROGRAM HISTORY LOG:
C   08-07-20  L. BENJAMIN ORIGINAL VERSION
C
C USAGE:    CALL MWISDOMSTA (ATIME,NSTA,STANAM,PROVDR,LAT,LON,
C           ELEVTIMEOB,STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     STANAM   - CA      STATION NAMES
C     PROVDR   - CA      DATA PROVIDER NAMES
C     LAT      - RA      LATITUDES (N)
C     LON      - RA      LONGITUDES (E)
C     ELEV     - RA      ELEVATION (M)
C     TIMEOB   - CA      YYJJJHHMM OBSERVATION TIMES
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS WISDOM NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, M_MKI4TM, MWISDOMCLS, MSFILES, M_MKFNAM, 
C                M_MKWFNM, MWISDOMRDSTA, MWISDOMFLTR, MMADISOPEN,
C                MMADISCLS1
C     NETCDF:    NCINQ, NCDINQ
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT BEFORE CALLING THIS ROUTINE.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXWISDOM_P IN
C     madiscon.f.  IF AFTER TIME & DOMAIN FILTERING THERE ARE MORE
C     THAN MXWISDOM_P RECORDS THIS ROUTINE WILL RETURN WITH THE
C     "TOO MANY RECORDS" ERROR (TOO_MANY_REC_P).  THIS SHOULD ALERT
C     THE USER TO RESTRUCTURE HIS/HER CODE TO CHANGE HOW DATA
C     ARE BEING RETRIEVED:  E.G., USE A SMALLER TIME WINDOW AND
C     CALL THIS ROUTINE TWICE -- GET THE DESIRED RESULT BUT WITHOUT
C     EXCEEDING THE MAXIMUM NUMBER OF RECORDS LEGALLY HANDLED BY
C     THE MADIS CODE.
C   - THIS ROUTINE SHOULD BE CALLED WHENEVER ACCESS TO A NEW TIME
C     IS DESIRED.
C   - FOLLOWING THIS CALL, MGETWISDOM SHOULD BE CALLED TO READ
C     IN WHATEVER OBSERVATIONS ARE DESIRED FOR THIS TIME.  THE INFO
C     STORED IN THE STRCCOM COMMON BY THIS ROUTINE IS USED BY THE OTHER
C     ROUTINES TO FIGURE OUT WHICH RECORDS IT NEEDS ON NETCDF FILES
C     OPENED IN THIS ROUTINE.
C   - THE MADISCOM PROVIDER ARRAYS (NPVD, PVDNAME, ETC.) HAVE WISDOM
C     PROVIDERS IN ROW 5.
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MWISDOMSTA (ATIME,NSTA,STANAM,PROVDR,LAT,LON,ELEV,
     1     TIMEOB,STATUS)


C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME,TIMEOB(*)
      CHARACTER*(*) STANAM(*),PROVDR(*)
      INTEGER NSTA,STATUS
      REAL LAT(*),LON(*),ELEV(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,K,L,I4TIME,NFILES,START_TIME,RCODE
      INTEGER NDIMS,NVARS,NGATTS
      LOGICAL KEEP_GOING
      CHARACTER*9 FTIME
      CHARACTER*31 DUMMY

      INTEGER OBTIME(MXWISDOM_P*4),FNUML(MXWISDOM_P*4)
      INTEGER RNUML(MXWISDOM_P*4)
      CHARACTER*10 STANAML(MXWISDOM_P*4)
      CHARACTER*(LDPNAM_P) PROVDRL(MXWISDOM_P*4)
      INTEGER NSTANEW,SUBSRC(MXWISDOM_P*4)
      REAL LATL(MXWISDOM_P*4),LONL(MXWISDOM_P*4),ELEVL(MXWISDOM_P*4)

      EQUIVALENCE(PROVDRL,TMP_L1_C1)
      EQUIVALENCE(LATL,TMP_L1_N1)
      EQUIVALENCE(LONL,TMP_L1_N2)
      EQUIVALENCE(ELEVL,TMP_L1_N3)

C     ------------------------------------------------------------------
C     IF THE WISDOM SUBSYSTEM HASN'T BEEN INITIALIZED, RETURN WITH 
C     ERROR.  OTHERWISE, CLOSE ANY OPEN NETCDF FILES AND INITIALIZE 
C     OTHER DATA STRUCTURES.
C     ------------------------------------------------------------------
      IF(WISDOM_INIT.NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MWISDOMSTA: SELECTED SUBSYSTEM NOT INITIALIZED '//
     1               '- WISDOM')
         RETURN
      ENDIF

      CALL M_MKI4TM(ATIME,I4TIME,STATUS)
      IF(STATUS.NE.SUCCESS_P)THEN
         CALL MERROR('MWISDOMSTA: INVALID TIME')
         RETURN
      ENDIF
      CALL MWISDOMCLS
      LAST_WISDOM_ATIME = '         '
      WISDOM_NFILES = 0
      WISDOM_LNUM = 0
      KEEP_GOING = .TRUE.
      CDTYPE = WISDOM_DS_P
      CDBTYPE = WISDOM_DBTYPE

C     ------------------------------------------------------------------
C     LOOP THROUGH THE DATASETS.
C     ------------------------------------------------------------------
      DO 1 I = 1, MAX_WISDOMDSET_P

C     ------------------------------------------------------------------
C     DETERMINE HOW MANY FILES NEED TO BE READ IN TO SATISFY THE TIME
C     WINDOW.
C     ------------------------------------------------------------------
         IF(WISDOMDSET_ENBL(I))THEN

            CALL MSFILES(MAX_SFCDSET_P+MAX_UAPTDSET_P+MAX_HYDRODSET_P+
     1           MAX_SATWDSET_P+MAX_SATSDSET_P+MAX_SATRDSET_P+
     1           MAX_SNOWDSET_P+I,
     1           I4TIME,START_TIME,NFILES)
            IF(NFILES.GT.WISDOM_MXSTRF/MAX_WISDOMDSET_P)THEN
               NSTA = 0
               LAST_WISDOM_ATIME = '         '
               STATUS = TOO_MANY_REC_P
               CALL MERROR('MWISDOMSTA: TOO MANY RECORDS REQUESTED')
               RETURN
            ENDIF

            K = 1

C     ------------------------------------------------------------------
C     LOOP FOR ALL FILES IN THE DATASET:
C     - CREATE THE FILENAME.
C     - OPEN THE FILE AND GET THE NO. OF RECORDS, STORE NCID & NREC.
C       IN COMMON FOR SUBSEQUENT READS.
C     - READ IN THE STATION INFO INTO LOCAL ARRAYS.
C     ------------------------------------------------------------------
            DO 5 J = 1, NFILES

               WISDOM_NFILES = WISDOM_NFILES + 1
               CALL M_MKFNAM(START_TIME,FTIME,STATUS)
               START_TIME = START_TIME + WISDOMDSET_INCR(I)

               CALL M_MKWFNM(FTIME,WISDOM_FNAME(WISDOM_NFILES),STATUS)

               CALL MMADISOPEN(WISDOMDIR(I),WISDOMDIRLEN(I),
     1                         WISDOM_FNAME(WISDOM_NFILES),
     2                         WISDOM_NCID(WISDOM_NFILES),RCODE)
               IF(RCODE.NE.0)THEN
                  WISDOM_NCID(WISDOM_NFILES) = -1
                  GO TO 10
               ENDIF

               CALL NCINQ(WISDOM_NCID(WISDOM_NFILES),NDIMS,NVARS,NGATTS,
     1                    WISDOM_RECDIM(WISDOM_NFILES),RCODE)
               IF(RCODE.NE.0)GO TO 10
               CALL NCDINQ(WISDOM_NCID(WISDOM_NFILES),
     1                     WISDOM_RECDIM(WISDOM_NFILES),DUMMY,
     2                     WISDOM_NRECS(WISDOM_NFILES),RCODE)
               IF(RCODE.NE.0.OR.WISDOM_NRECS(WISDOM_NFILES).EQ.0)
     1              GO TO 10

C     ------------------------------------------------------------------
C     IF WE'VE SOMEHOW EXCEEDED THE DIMENSION OF OUR ARRAYS, DON'T
C     TRY TO READ ANYMORE, BUT DO RETURN WITH WHAT WE'VE ALREADY GOT.
C     NOTE THAT WE DON'T DECLARE A FATAL ERROR, AS WE DO WHEN THE
C     POST-FILTERED AMOUNT IS GREATHER THAN MXWISDOM_P.  THIS IS BECAUSE
C     THIS ERROR WOULD BE A RESULT OF INTERNAL LOGIC PROBLEMS AND
C     THE USER WHO STUMBLES ACROSS IT SHOULDN'T BE EXPECTED TO REWRITE
C     HIS CODE TO COMPENSATE...
C     ------------------------------------------------------------------
               IF(K-1+WISDOM_NRECS(WISDOM_NFILES).GT.MXWISDOM_P*4)THEN
                  KEEP_GOING = .FALSE.
                  CALL MMADISCLS1(WISDOM_NCID(WISDOM_NFILES),
     1                 WISDOMDIR(I),WISDOMDIRLEN(I),
     2                 WISDOM_FNAME(WISDOM_NFILES))
                  WISDOM_NCID(WISDOM_NFILES) = -1
                  WISDOM_NFILES = WISDOM_NFILES - 1
                  GO TO 100
               ENDIF

               CALL MWISDOMRDSTA(I+MAX_SFCDSET_P+MAX_UAPTDSET_P+
     1              MAX_HYDRODSET_P+MAX_SATWDSET_P+
     1              MAX_SATSDSET_P+MAX_SATRDSET_P+MAX_SNOWDSET_P
     1              ,WISDOM_NCID(WISDOM_NFILES),
     2              WISDOM_RECDIM(WISDOM_NFILES),1,
     3              WISDOM_NRECS(WISDOM_NFILES),MXWISDOM_P*4,
     4              OBTIME(K),STANAML(K),PROVDRL(K),LATL(K),LONL(K),
     5              ELEVL(K),SUBSRC(K),STATUS)
               IF(STATUS.EQ.SUCCESS_P)THEN
C ELEV and STAID

C     ------------------------------------------------------------------
C     PUT THE FILE AND RECORD NUMBERS, AND THE SOURCE, INTO COMMON AND
C     UPDATE K FOR NEXT FILE IN THIS DATASET.
C     ------------------------------------------------------------------
                  DO 4 L = K, K + WISDOM_NRECS(WISDOM_NFILES) - 1
                     FNUML(L) = WISDOM_NFILES
                     RNUML(L) = L - K + 1
 4                CONTINUE
                  K = K + WISDOM_NRECS(WISDOM_NFILES)
                  WISDOM_SOURCE(WISDOM_NFILES) = I
                  GO TO 5
               ENDIF

C     ------------------------------------------------------------------
C     ERROR WITH THE NETCDF FILE.  CLOSE IT (IF OPEN) AND RELEASE ITS
C     SLOT IN THE COMMON.
C     ------------------------------------------------------------------
 10            IF(WISDOM_NCID(WISDOM_NFILES).GE.0)
     1            CALL MMADISCLS1(WISDOM_NCID(WISDOM_NFILES),
     2              WISDOMDIR(I),WISDOMDIRLEN(I),
     3              WISDOM_FNAME(WISDOM_NFILES))
               WISDOM_NCID(WISDOM_NFILES) = -1
               WISDOM_NFILES = WISDOM_NFILES - 1

 5          CONTINUE

C     ------------------------------------------------------------------
C     IF WE HAVE ANYTHING FOR THIS DATASET, FILTER RECS WE DON'T WANT:
C     - MISSING LAT, LON OR P
C     - OUTSIDE THE TIME WINDOW
C     - PROVIDERS THAT HAVE BEEN DISABLED BY MSETPVDR
C     ------------------------------------------------------------------
 100        K = K - 1
            IF(K.EQ.0)THEN
               IF(KEEP_GOING)THEN
                  GO TO 1
               ELSE
                  GO TO 900
               ENDIF
            ENDIF

            CALL MWISDOMFLTR(ATIME,MINBCK,MINFWD,RECWIN,MISS_P,
     1           PROVDR_ENBL(1,9),K,OBTIME,STANAML,PROVDRL,
     2           SUBSRC,LATL,LONL,ELEVL,FNUML,RNUML,NSTANEW)

C     ------------------------------------------------------------------
C     THE CALLER IS EXPECTED TO HAVE MXWISDOM_P RECORDS AVAILABLE.  IF
C     THIS WOULD PUT HIM OVER THE TOP, RETURN WITH AN ERROR (SEE
C     REMARKS SECTION ABOVE).
C     ------------------------------------------------------------------
            IF(NSTANEW+WISDOM_LNUM.GT.MXWISDOM_P)THEN
               NSTA = 0
               LAST_WISDOM_ATIME = '         '
               STATUS = TOO_MANY_REC_P
               CALL MERROR('MWISDOMSTA: TOO MANY RECORDS REQUESTED')
               RETURN
            ENDIF

C     ------------------------------------------------------------------
C     TRANSFER REMAINING RECORDS TO CALLER'S ARRAYS, AND UPDATE INFO
C     IN COMMON.
C     ------------------------------------------------------------------
            DO 200 J = 1, NSTANEW
               K = WISDOM_LNUM + J
               STANAM(K) = STANAML(J)
               PROVDR(K) = PROVDRL(J)
               LAT(K) = LATL(J)
               LON(K) = LONL(J)
               ELEV(K) = ELEVL(J)
               CALL M_MKFNAM(OBTIME(J),TIMEOB(K),STATUS)

               WISDOM_FNUM(K) = FNUML(J)
               WISDOM_RNUM(K) = RNUML(J)

 200        CONTINUE

            WISDOM_LNUM = WISDOM_LNUM + NSTANEW

         ENDIF

         IF(.NOT.KEEP_GOING)GO TO 900

 1    CONTINUE

C     ------------------------------------------------------------------
C     IF WE GOT ANYTHING AT ALL, TELL CALLER HOW MANY STATIONS AND
C     UPDATE THE ATIME KEPT IN COMMON SO SUBSEQUENT READS FOR THE
C     SAME TIME WILL USE THE FILE/RECORD INFO WE JUST WORKED SO HARD
C     TO CREATE...
C     ------------------------------------------------------------------
 900  IF(WISDOM_LNUM.GT.0)THEN
         NSTA = WISDOM_LNUM
         LAST_WISDOM_ATIME = ATIME
         STATUS = SUCCESS_P
      ELSE
         NSTA = 0
         LAST_WISDOM_ATIME = '         '
         STATUS = NO_DATA_P
         CALL MERROR('MWISDOMSTA: NO DATA FOR '//ATIME)
      ENDIF

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
