C$$$   SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    M_EQVLAT    CALCULATES LAMBERT CONFORMAL TANGENT
C
C   PRGMMR:  BARTH, MIKE    ORG: FSL            DATE: 99-09-02
C
C ABSTRACT:  CALCULATES EQUIVALENT SINGLE TANGENT FROM DOUBLE TANGENT
C            LAMBERT CONFORMAL PROJECTION FORMULATION
C
C PROGRAM HISTORY LOG:
C
C   99-09-02  M. BARTH    ORIGINAL VERSION
C
C
C USAGE:           M_EQVLAT = M_EQVLAT(XLAT1,XLAT2)
C
C   INPUT ARGUMENT LIST:
C   XLAT1       - REAL           1ST LAMBERT CONFORMAL TANGENT LAT
C   XLAT2       - REAL           2ND LAMBERT CONFORMAL TANGENT LAT
C
C   OUTPUT ARGUMENT LIST:
C   M_EQVLAT    - REAL           SINGLE TANGENT
C
C REMARKS: - XLAT1, XLAT2, M_EQVLAT UNITS ARE DEGREES (N IS +)
C          - REFERENCE FOR EQUIVALENCY OF SINGLE- & DOUBLE-TANGENT
C            LAMBERT CONFORMAL CONFIGURATIONS:
C            TAYLOR, ALBION D., 1997:  CONFORMAL MAP TRANSFORMATIONS FOR
C                                      METEROLOGICAL MODELERS.
C            COMPUTERS AND GEOSCIENCES, V23, NO. 1 (FEBRUARY 1997)
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE: UNIX
C
C$$$
C
        REAL FUNCTION M_EQVLAT (XLAT1,XLAT2)
C*  WRITTEN ON 3/31/94 BY DR. ALBION TAYLOR  NOAA / OAR / ARL
        PARAMETER (PI=3.14159265358979,RADPDG=PI/180,DGPRAD=180/PI)
        SIND(X) = SIN (RADPDG*X)
        SINL1 = SIND (XLAT1)
        SINL2 = SIND (XLAT2)
        IF (ABS(SINL1 - SINL2) .GT. .001) THEN
          AL1 = LOG((1. - SINL1)/(1. - SINL2))
          AL2 = LOG((1. + SINL1)/(1. + SINL2))
        ELSE
C  CASE LAT1 NEAR OR EQUAL TO LAT2
          TAU = - (SINL1 - SINL2)/(2. - SINL1 - SINL2)
          TAU = TAU*TAU
          AL1  = 2. / (2. - SINL1 - SINL2) * (1.    + TAU *
     C                                       (1./3. + TAU *
     C                                       (1./5. + TAU *
     C                                       (1./7.))))
          TAU =   (SINL1 - SINL2)/(2. + SINL1 + SINL2)
          TAU = TAU*TAU
          AL2  = -2. / (2. + SINL1 + SINL2) * (1.    + TAU *
     C                                        (1./3. + TAU *
     C                                        (1./5. + TAU *
     C                                        (1./7.))))
        ENDIF
        M_EQVLAT = ASIN((AL1 + AL2) / (AL1 - AL2))/RADPDG
        RETURN
        END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
