C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MSFCSNOW    GET COOP SNOW OBS
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 04-03-24
C
C ABSTRACT: GET COOP SNOW COVER AND SNOW FALL OBS FOR ALL STATIONS IN 
C   ONE NETCDF FILE FOR ONE TIME.
C
C PROGRAM HISTORY LOG:
C   04-03-24  M. BARTH    ORIGINAL VERSION
C   04-10-16  L. BENJAMIN ADDED NO SUCH VARIABLE CHECK FOR QCA CHECKS
C
C USAGE:    CALL MSFCSNOW (VCN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)
C
C   INPUT ARGUMENT LIST:
C     VCN      - I       VARIABLE CODE NUMBER FOR SNOW COVER
C     FNUM     - I       FILE NUMBER (INDEX IN COMMON) OF NETCDF FILE
C
C   OUTPUT ARGUMENT LIST:
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - RA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - RA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       SUCCESS_P OR ERROR CODE
C
C   INPUT FILES:
C     NETCDF FILE OPENED USING DATA STRUCTURES FOR FNUM IN STRCCOM
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MGTNUM, MGTCHR
C
C REMARKS:
C   - THIS ROUTINE IS ASSUMED TO BE CALLED BY A HIGHER-LEVEL MADIS
C     ROUTINE, SO NO ERROR CHECKING IS DONE ON THE INPUT VARIABLES.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MSFCSNOW (VCN,FNUM,OB,QCDESC,QCAPP,QCRES,STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      INTEGER VCN,FNUM,STATUS
      REAL OB(*),QCAPP(*),QCRES(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      REAL OBTMP(MXSFC_P,2),QCATMP(MXSFC_P,2),QCRTMP(MXSFC_P,2)
      CHARACTER*1 QCDTMP(MXSFC_P,2)
      INTEGER I,LEN1REC,NMLEN(2)
      CHARACTER*12 VRNAM(2)
      LOGICAL QCMISS(2)

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(OBTMP,TMP_L3_N1)
      EQUIVALENCE(QCATMP,TMP_L3_N2)
      EQUIVALENCE(QCRTMP,TMP_L3_N3)
      EQUIVALENCE(QCDTMP,TMP_L3_C1)

C     ------------------------------------------------------------------
C     DATA STATEMENTS (KEEP AT BOTTOM OF DECLARATIONS)
C     ------------------------------------------------------------------
      DATA VRNAM/'snowDepth6H','snowDepth24H'/
      DATA NMLEN/11,12/

C     ------------------------------------------------------------------
C     READ IN THE 6H VERSION OF THE VARIABLE INTO COLUMN 1 OF THE
C     LOCAL ARRAYS, AND GET THE 24H VERSION INTO COLUMN 2.  THE SNOW
C     COVER OBS ARE TAKEN MANUALLY BY THE COOP OBSERVER, AND THESE ARE
C     STRATIFIED INTO 6H OR 24H SIMPLY AS A FUNCTION OF HOW OFTEN THE
C     OBSERVER GOES OUTSIDE TO MEASURE THEM.  THEREFORE, YOU WON'T SEE
C     BOTH VARIABLES IN USE AT THE SAME STATION.  WE'LL LOOK FIRST IN
C     THE 6H VARIABLE, AND IF THE OB IS MISSING, WE'LL USE THE 24H
C     VARIABLE (MISSING OR NOT).
C
C     NOTE THAT, CONTRARY TO GENERAL PRACTICE, WE ASSUME THAT BOTH
C     VARIABLES HAVE QC STRUCTURES.
C   
C     ALSO NOTE THAT WE CONVERT FROM MM TO M.
C     ------------------------------------------------------------------

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
      QCSTATUS = EQCOK_P

      
      DO I = 1, 2
         QCMISS(I) = .FALSE.
         CALL MGTNUM(VRNAM(I)(1:NMLEN(I)),SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),MISS_P,
     1               OBTMP(1,I),STATUS)
         IF(STATUS.NE.SUCCESS_P)RETURN

         CALL MGTNUM(VRNAM(I)(1:NMLEN(I))//'QCA',SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),MISS_P,
     2               QCATMP(1,I),STATUS)
         IF(STATUS.EQ.VAR_NOTINDB_P)THEN
            QCMISS(I) = .TRUE.
            STATUS = SUCCESS_P
         ELSE IF(STATUS.EQ.SUCCESS_P)THEN

            CALL MGTNUM(VRNAM(I)(1:NMLEN(I))//'QCR',SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),MISS_P,
     2               QCRTMP(1,I),STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN

            CALL MGTCHR(VRNAM(I)(1:NMLEN(I))//'DD',SFC_NCID(FNUM),
     1               SFC_RECDIM(FNUM),1,SFC_NRECS(FNUM),
     2               QCDTMP(1,I),LEN1REC,STATUS)
            IF(STATUS.NE.SUCCESS_P)RETURN
         ENDIF
      ENDDO
      
C     SET QC MISSING UNLESS WE HAVA IT ASSIGNED AND POSSIBLY DATA
      IF(QCMISS(1).AND.QCMISS(2))THEN
         QCSTATUS = EQCFAILED_P
      ELSE
         QCSTATUS = EQCOK_P
      ENDIF

      DO I = 1, SFC_NRECS(FNUM)
         
         IF(.NOT.QCMISS(1).AND.OBTMP(I,1).NE.MISS_P)THEN

            OB(I) = OBTMP(I,1)
            QCAPP(I) = QCATMP(I,1)
            QCRES(I) = QCRTMP(I,1)
            QCDESC(I) = QCDTMP(I,1)

         ELSE IF(.NOT.QCMISS(2).AND.OBTMP(I,2).NE.MISS_P)THEN
               
            OB(I) = OBTMP(I,2)
            QCAPP(I) = QCATMP(I,2)
            QCRES(I) = QCRTMP(I,2)
            QCDESC(I) = QCDTMP(I,2)
               
         ELSE IF(OBTMP(I,1).NE.MISS_P)THEN
            OB(I) = OBTMP(I,1)
            QCAPP(I) = 0
            QCRES(I) = 0
            QCDESC(I) = 'Z'
         ELSE
            OB(I) = OBTMP(I,2)
            QCAPP(I) = 0
            QCRES(I) = 0
            QCDESC(I) = 'Z'
         ENDIF
         
         IF(OB(I).NE.MISS_P)OB(I) = OB(I)/1000.
            
      ENDDO

      RETURN
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
