C$$$  SUBPROGRAM DOCUMENTATION BLOCK
C                .      .    .                                       .
C SUBPROGRAM:    MGETSNOW   GET SNOW OBS & QC INFO FOR ONE VARIABLE
C   PRGMMR: L.  BENJAMIN     ORG: FSL        DATE: 05-11-18
C
C ABSTRACT: READ SNOW OBS & QC INFO FOR ALL STATIONS FOR ONE VARIABLE
C   AND TIME.
C
C PROGRAM HISTORY LOG:
C   05-11-18  L. BENJAMIN ORIGINAL VERSION
C
C USAGE:    CALL MGETSNOW (ATIME,VCODE,NSTA,NOBS,OB,QCDESC,QCAPP,QCRES,
C                           STATUS)
C
C   INPUT ARGUMENT LIST:
C     ATIME    - C       YYJJJHHMM OF THE DATA TO BE READ
C     VCODE    - C       VARIABLE CODE NAME
C
C   OUTPUT ARGUMENT LIST:
C     NSTA     - I       NUMBER OF STATIONS RETURNED
C     NOBS     - I       NUMBER OF NON-MISSING OBS (<= NSTA)
C     OB       - RA      OBSERVATIONS IN M/K/S UNITS
C     QCDESC   - CA      QC DATA DESCRIPTORS
C     QCAPP    - IA      QC APPLIED WORD (SHOWS CHECKS APPLIED)
C     QCRES    - IA      QC RESULTS WORD (GOOD/BAD FOR EACH CHECK)
C     STATUS   - I       0 - SUCCESS, OR ERROR CODE
C
C   INPUT FILES:
C     MADIS SNOW NETCDF FILES FOR ATIME
C
C SUBPROGRAMS CALLED:
C     UNIQUE:    MERROR, MGETVCN, MGTNUM, MGTCHR, MQCFLTR
C
C REMARKS:
C   - THE CALLER MUST CALL MINIT AND MSNOWSTA BEFORE CALLING THIS
C     ROUTINE.  MSNOWSTA SHOULD BE CALLED FIRST WHENEVER ACCESS TO
C     A NEW TIME IS DESIRED.  IT STORES INFO IN THE STRCCOM COMMON
C     THAT IS USED BY THIS ROUTINE TO FIGURE OUT WHICH RECORDS ARE
C     NEEDED ON NETCDF FILES OPENED BY MSNOWSTA.
C   - DOUBLE & CHARACTER DATA TYPES ARE NOT HANDLED BY THIS ROUTINE.
C   - THE CALLER SHOULD DIMENSION ARRAYS TO MATCH MXSNOW_P IN
C     madiscon.f.
C   - SEE madistmp.f FOR AN EXPLANATION OF HOW TEMPORARY STORAGE
C     IS HANDLED (ALL ARRAYS NAMED *TMP*).
C
C ATTRIBUTES:
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$

      SUBROUTINE MGETSNOW(ATIME,VCODE,NSTA,NOBS,OB,QCDESC,QCAPP,QCRES,
     1                     STATUS)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'
      INCLUDE 'MADISCON'
      INCLUDE 'MADISCOM'
      INCLUDE 'STRCCOM'
      INCLUDE 'MADISTMP'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*9 ATIME
      CHARACTER*(*) VCODE
      INTEGER NSTA,NOBS,QCAPP(*),QCRES(*),STATUS
      REAL OB(*)
      CHARACTER*1 QCDESC(*)

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER I,J,FNUM,DSN,LEN1REC,DUMMY,VCN
      REAL OBTMP(MXSNOW_P),QCATMP(MXSNOW_P),QCRTMP(MXSNOW_P)
      CHARACTER*1 QCDTMP(MXSNOW_P),VCT
      LOGICAL PROC_FILE(SNOW_MXSTRF)

C     ------------------------------------------------------------------
C     TEMPORARY STORAGE DEFINITIONS
C     ------------------------------------------------------------------
      EQUIVALENCE(OBTMP,TMP_L1_N1)
      EQUIVALENCE(QCATMP,TMP_L1_N2)
      EQUIVALENCE(QCRTMP,TMP_L1_N3)
      EQUIVALENCE(QCDTMP,TMP_L1_C1)

C     ------------------------------------------------------------------
C     IF THE SNOW SUBSYSTEM HASN'T BEEN INITIALIZED, OR IF THE 
C     REQUESTED TIME DOESN'T MATCH THE TIME LAST PROCESSED BY MSNOWSTA,
C     OR IF THE VCODE IS CLEARLY ILLEGAL, RETURN WITH ERROR.
C     ------------------------------------------------------------------
      IF(SNOW_INIT.NE.INIT_P)THEN
         STATUS = SELSUB_NOTINIT_P
         CALL MERROR('MGETSNOW: SELECTED SUBSYSTEM NOT INITIALIZED -'//
     1               ' SNOW')
         GO TO 900
      ELSE IF(ATIME.NE.LAST_SNOW_ATIME.OR.ATIME.EQ.'         ')THEN
         STATUS = TIME_NOTINIT_P
         CALL MERROR('MGETSNOW: TIME NOT INITIALIZED BY MSNOWSTA')
         GO TO 900
      ELSE 
         CALL MGETVCN(VCODE,VCN,VCT,STATUS)
         IF(STATUS.NE.SUCCESS_P)GO TO 900
      ENDIF

C     ------------------------------------------------------------------
C     SET THE CURRENT DATA TYPE.
C     ------------------------------------------------------------------
      CDTYPE = SNOW_DS_P

C     ------------------------------------------------------------------
C     FILL IN MISSING FLAGS FOR ALL POSSIBLE RECORDS IN CALLER'S ARRAY,
C     INDICATE THAT WE HAVEN'T PROCESSED ANY FILES YET.
C     THEN LOOP THROUGH THE FILES THAT ARE NEEDED AND PUT IN REAL DATA
C     WHERE AVAILABLE.
C     ------------------------------------------------------------------
      NSTA = SNOW_LNUM
      IF(NSTA.EQ.0)THEN
         STATUS = NO_DATA_P
         GO TO 900
      ENDIF

      FNUM = 0

      DO 1 I = 1, NSTA
         OB(I) = MISS_P
         OBTMP(I) = MISS_P
         QCDESC(I) = 'Z'
         QCAPP(I) = 0
         QCRES(I) = 0
 1    CONTINUE

      DO 2 I = 1, SNOW_MXSTRF
         PROC_FILE(I) = .FALSE.
 2    CONTINUE

C     ------------------------------------------------------------------
C     NOTE THAT WE LOOP THROUGH SNOW_FNUM TO SEE WHICH FILES ARE NEEDED
C     AND NOT THROUGH SNOW_NFILES.  THIS IS DONE AS JUST BECAUSE A FILE
C     GOT READ DOESN'T MEAN ANY OF ITS RECORDS ACTUALLY WERE EXTRACTED
C     WHEN ALL THE FILTERING WAS DONE IN MSNOWSTA.  THEREFORE, WE'LL
C     ONLY PROCESS EACH FILE WITH RECORDS IN USE.
C     ------------------------------------------------------------------
      DO 100 I = 1, NSTA

C     ------------------------------------------------------------------
C     ALREADY HANDLED THIS FILE.
C     ------------------------------------------------------------------
         IF(PROC_FILE(SNOW_FNUM(I)))GO TO 100

         FNUM = SNOW_FNUM(I)
         PROC_FILE(FNUM) = .TRUE.
         DSN = MAX_SFCDSET_P + MAX_UAPTDSET_P + MAX_HYDRODSET_P +
     1        MAX_SATWDSET_P + MAX_SATSDSET_P + MAX_SATRDSET_P + 
     2        SNOW_SOURCE(FNUM)

C     ------------------------------------------------------------------
C     THE VARIABLE'S NOT ASSOCIATED WITH THIS SOURCE DATASET.
C     ------------------------------------------------------------------
         IF(VLEN(VCN,DSN).EQ.0)GO TO 100

C     ------------------------------------------------------------------
C     THE VARIABLE'S DOUBLE OR CHARACTER DATA TYPE:  THIS WILL BE
C     TRUE FOR ANY DATASET FOR WHICH THIS VARIABLE APPLIES, AND IS
C     AN ILLEGAL OPTION.
C     ------------------------------------------------------------------
         IF(VDTYPE(VCN,DSN).EQ.'d'.OR.VDTYPE(VCN,DSN).EQ.'c')THEN
            STATUS = INV_DTYPE_P
            CALL MERROR('MGETSNOW: INVALID VARIABLE DATA TYPE')
            GO TO 900
         ENDIF

C     ------------------------------------------------------------------
C     IF THE VARIABLE NEEDS TO BE CREATED FROM OTHER VARIABLES, CALL
C     A SUBROUTINE TO FILL IN THE LOCAL ARRAYS.  OTHERWISE, READ THE
C     VARIABLE, AND IF AVAILABLE, QC INFO.  IF THERE'S AN ERROR,
C     THE SUBROUTINES WILL HAVE SET STATUS & CALLED MERROR.
C
C     AT THE INITIAL WRITING, NO VARIABLES CALL FOR SPECIAL HANDLING.
C     ------------------------------------------------------------------
         CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN)),SNOW_NCID(FNUM),
     1               SNOW_RECDIM(FNUM),1,SNOW_NRECS(FNUM),MISS_P,
     2               OBTMP,STATUS)

         IF(STATUS.NE.SUCCESS_P)GO TO 900

C     ASSUME QC OK, SET FOR DIFFERNET CONDITIONS
         QCSTATUS = EQCOK_P

         IF(VQC(VCN,DSN).EQ.'Q')THEN

            CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCA',
     1                  SNOW_NCID(FNUM),SNOW_RECDIM(FNUM),1,
     2                  SNOW_NRECS(FNUM),MISS_P,QCATMP,STATUS)

            IF(STATUS.EQ.VAR_NOTINDB_P)THEN
               QCSTATUS = EQCFAILED_P
               STATUS = SUCCESS_P
               DO 11 J = 1, SNOW_NRECS(FNUM)
                  
                  QCDTMP(J) = 'Z'
                  QCATMP(J) = 0
                  QCRTMP(J) = 0

 11               CONTINUE
            ELSE IF(STATUS.NE.SUCCESS_P)THEN
               GO TO 900
            ELSE
               CALL MGTNUM(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'QCR',
     1                  SNOW_NCID(FNUM),SNOW_RECDIM(FNUM),1,
     2                  SNOW_NRECS(FNUM),MISS_P,QCRTMP,STATUS)
               IF(STATUS.NE.SUCCESS_P)GO TO 900

               CALL MGTCHR(VNAME(VCN,DSN)(1:VLEN(VCN,DSN))//'DD',
     1                  SNOW_NCID(FNUM),SNOW_RECDIM(FNUM),1,
     2                  SNOW_NRECS(FNUM),QCDTMP,LEN1REC,STATUS)
               IF(STATUS.NE.SUCCESS_P)GO TO 900               
            ENDIF
         ELSE
            QCSTATUS = EQCFAILED_P

            DO 10 J = 1, SNOW_NRECS(FNUM)

               QCDTMP(J) = 'Z'
               QCATMP(J) = 0
               QCRTMP(J) = 0

 10         CONTINUE

         ENDIF


C     ------------------------------------------------------------------
C     DO ANY REQUESTED QC FILTERING.  NOTE THAT THIS IS DONE INSIDE THE
C     DO 100 LOOP SO THAT MQCFLTR CAN HANDLE EACH SNOW DATASET
C     INDIVIDUALLY.  THIS IS NEEDED TO COVER THE CASE OF QC INFO NOT
C     BEING AVAILABLE FOR ALL SNOW DATASETS, BUT IS AVAILABLE FOR SOME.
C     ------------------------------------------------------------------
         CALL MQCFLTR(VCN,DSN,SNOW_NRECS(FNUM),1,QCDTMP,DUMMY,DUMMY,
     1                OBTMP)

C     ------------------------------------------------------------------
C     EXTRACT DESIRED RECORDS INTO CALLER'S ARRAY.
C     ------------------------------------------------------------------

         DO 120 J = I, NSTA

            IF(SNOW_FNUM(J).NE.FNUM)GO TO 120

            OB(J) = OBTMP(SNOW_RNUM(J))
            QCDESC(J) = QCDTMP(SNOW_RNUM(J))
            QCAPP(J) = QCATMP(SNOW_RNUM(J))
            QCRES(J) = QCRTMP(SNOW_RNUM(J))

 120     CONTINUE

 100  CONTINUE


 900  IF(STATUS.NE.SUCCESS_P)THEN

         NSTA = 0
         NOBS = 0

      ELSE

C     ------------------------------------------------------------------
C     COUNT UP THE NUMBER OF NON-MISSING OBS ACTUALLY RETURNED.
C     ------------------------------------------------------------------
         NOBS = 0

         DO 121 J = 1, NSTA
            IF(OB(J).NE.MISS_P)NOBS = NOBS + 1
 121     CONTINUE

         IF(NOBS.EQ.0)THEN
            NSTA = 0
            STATUS = NO_DATA_P
         ENDIF

      ENDIF

      RETURN
      END

C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
