C$$$  SUBPROGRAM DOCUMENTATION BLOCK 
C                .      .    .                                       . 
C SUBPROGRAM:    M_CBSRCH    BINARY SEARCH FOR CHARACTER DATA          
C   PRGMMR: M. BARTH         ORG: FSL        DATE: 01-07-26
C 
C ABSTRACT: IMPLEMENT A BINARY SEARCH FOR A TARGET STRING IN CHARACTER
C   ARRAY.  CAN BE USED TO FIND A MATCH OR AS PART OF A BINARY INSERTION
C   SORT
C 
C PROGRAM HISTORY LOG: 
C   01-07-26  M. BARTH    ORIGINAL VERSION
C 
C USAGE:    CALL M_CBSRCH (S,T,N,IND,MATCH)                                
C
C   INPUT ARGUMENT LIST: 
C     
C     S        - CA      CHARACTER ARRAY TO BE SEARCHED
C     T        - C       TARGET SEARCH STRING
C     N        - I       NUMBER OF ARRAY ELEMENTS IN S          
C 
C   OUTPUT ARGUMENT LIST:   
C     IND      - I       INDEX AT WHICH T BELONGS IN S
C     MATCH    - L       .TRUE.  -- T IS ALREADY IN THE LIST (AT I)
C                        .FALSE. -- T WASN'T ALREADY IN THE LIST,
C
C REMARKS:
C
C ATTRIBUTES: 
C   LANGUAGE: FORTRAN-77 + EXTENSIONS
C   MACHINE:  UNIX
C$$$ 

      SUBROUTINE M_CBSRCH(S,T,N,IND,MATCH)

C     ------------------------------------------------------------------
C     INCLUDES AND COMMONS
C     ------------------------------------------------------------------
      INCLUDE 'IMPLICIT'

C     ------------------------------------------------------------------
C     ARGUMENTS
C     ------------------------------------------------------------------
      CHARACTER*(*) S(*),T
      INTEGER N,IND
      LOGICAL MATCH

C     ------------------------------------------------------------------
C     LOCAL
C     ------------------------------------------------------------------
      INTEGER ILOW,IHIGH,IMID


C     *****************************************************************
C     ******************* BEGIN OF MODULE M_CBSRCH ********************
C     *****************************************************************

C     ------------------------------------------------------------------
C     INITIALIZE BINARY POINTERS.
C     ------------------------------------------------------------------
      ILOW = 1
      IHIGH = N
C
C     ------------------------------------------------------------------
C     PERFORM THE SEARCH.
C     ------------------------------------------------------------------

 1    IF(ILOW.GT.IHIGH)THEN
         
         IND = IHIGH + 1
         MATCH = .FALSE.
         RETURN
         
      ENDIF
      
      IMID = (ILOW + IHIGH) / 2
      
      IF(S(IMID).EQ.T)THEN
         
         IND = IMID
         MATCH = .TRUE.
         RETURN
         
      ENDIF
      
      IF(S(IMID).LT.T)THEN

         ILOW = IMID + 1

      ELSE

         IHIGH = IMID - 1

      ENDIF

      GO TO 1
     
      END
C**---------------------------------------------------------------------
C**REQUIRED STANDARD FSL DISCLAIMER (NOVEMBER 2000)
C**---------------------------------------------------------------------
C**  OPEN SOURCE LICENSE/DISCLAIMER,  FORECAST SYSTEMS LABORATORY
C**  NOAA/OAR/FSL, 325 BROADWAY BOULDER, CO 80305
C**
C**  THIS SOFTWARE IS DISTRIBUTED UNDER THE OPEN SOURCE DEFINITION, 
C**  WHICH MAY BE FOUND AT http://www.opensource.org/osd.html.
C**
C**  IN PARTICULAR, REDISTRIBUTION AND USE IN SOURCE AND BINARY FORMS,
C**  WITH OR WITHOUT MODIFICATION, ARE PERMITTED PROVIDED THAT THE 
C**  FOLLOWING CONDITIONS ARE MET:
C**
C**  - REDISTRIBUTIONS OF SOURCE CODE MUST RETAIN THIS NOTICE, THIS LIST
C**    OF CONDITIONS AND THE FOLLOWING DISCLAIMER.
C**
C**  - REDISTRIBUTIONS IN BINARY FORM MUST PROVIDE ACCESS TO THIS 
C**    NOTICE, THIS LIST OF CONDITIONS AND THE FOLLOWING DISCLAIMER, AND
C**    THE UNDERLYING SOURCE CODE.
C**
C**  - ALL MODIFICATIONS TO THIS SOFTWARE MUST BE CLEARLY DOCUMENTED, 
C**    AND ARE SOLELY THE RESPONSIBILITY OF THE AGENT MAKING THE 
C**    MODIFICATIONS.
C**
C**  - IF SIGNIFICANT MODIFICATIONS OR ENHANCEMENTS ARE MADE TO THIS
C**    SOFTWARE, THE FSL SOFTWARE POLICY MANAGER 
C**    (softwaremgr.fsl@noaa.gov) BE NOTIFIED.
C**
C**  THIS SOFTWARE AND ITS DOCUMENTATION ARE IN THE PUBLIC DOMAIN AND 
C**  ARE FURNISHED "AS IS."  THE AUTHORS, THE UNITED STATES GOVERNMENT,
C**  ITS INSTRUMENTALITIES, OFFICERS, EMPLOYEES, AND AGENTS MAKE NO 
C**  WARRANTY, EXPRESS OR IMPLIED, AS TO THE USEFULNESS OF THE SOFTWARE
C**  AND DOCUMENTATION FOR ANY PURPOSE.  THEY ASSUME NO RESPONSIBILITY 
C**  (1) FOR THE USE OF THE SOFTWARE AND DOCUMENTATION; OR (2) TO 
C**  PROVIDE TECHNICAL SUPPORT TO USERS.
C**---------------------------------------------------------------------
